Changeset 910

Timestamp:

Dec 4, 2009 5:14:10 PM (14 years ago)

Author:

toby

Message:

# on 2008/04/15 17:20:39, toby did:
macro recording
implement prompt/no prompt in GSAS window
implement run macros
new proc to run GSAS programs w/o a terminal window

File:

• trunk/gsascmds.tcl (modified) (16 diffs, 3 props)

trunk/gsascmds.tcl

@@ -735 +735 @@
     foreach phase $phaselist hist $histlist {
         hapinfo $hist $phase proftype set $expgui(newpeaktype)
+        RecordMacroEntry "hapinfo $hist $phase proftype set $expgui(newpeaktype)" 0
         hapinfo $hist $phase profterms set $expgui(newProfileTerms)
+        RecordMacroEntry "hapinfo $hist $phase profterms set $expgui(newProfileTerms)" 0
         for {set i 1} {$i <=  $expgui(newProfileTerms)} {incr i} {
             hapinfo $hist $phase pterm$i set [$w.ent${i} get]
+            RecordMacroEntry "hapinfo $hist $phase pterm$i set [$w.ent${i} get]" 0
             hapinfo $hist $phase pref$i set $expgui(ProfRef$i)
+            RecordMacroEntry "hapinfo $hist $phase pref$i set $expgui(ProfRef$i)" 0
         }
         set i [expr 1+$expgui(newProfileTerms)]
         hapinfo $hist $phase pcut set [$w.ent$i get]
+        RecordMacroEntry "hapinfo $hist $phase pcut set [$w.ent$i get]" 0
         incr expgui(changed) [expr 3 + $expgui(newProfileTerms)]
+        RecordMacroEntry "incr expgui(changed)" 0
     }
 }
@@ -1140 +1146 @@
     # Save the current exp file
     savearchiveexp
+    CantRecordMacroEntry "bkgedit"
     # disable the file change monitor if we will reload the .EXP file automatically
     if {$expgui(autoexpload)} {set expgui(expModifiedLast) 0}
@@ -1158 +1165 @@
 # run excledt
 proc excledit {} {
-    global expgui liveplot wishshell expmap
+    global expgui liveplot expmap
     set expnam [file root [file tail $expgui(expfile)]]
     # which histograms are ready for use?
@@ -1336 +1343 @@
 # run a GSAS program that does not require an experiment file
 proc runGSASprog {proglist "concurrent 1"} {
+    # save call to Macro file
+    RecordMacroEntry "runGSASprog [list $proglist] $concurrent" 0
     # if concurrent is 0, EXPGUI runs the GSAS program in background
     # -- this is not currently needed anywhere where the .EXP file is not.
@@ -1358 +1367 @@
 # run a GSAS program that requires an experiment file for input/output
 proc runGSASwEXP {proglist "concurrent 0"} {
+    # save call to Macro file
+    RecordMacroEntry "runGSASwEXP [list $proglist] $concurrent" 0
     # most programs that require the .EXP file change it and 
     # cannot be run concurrently
@@ -1393 +1404 @@
         if {$tcl_platform(platform) == "windows"} {
             append cmd " \"$expgui(gsasexe)/${prog}.exe $expnam \" "
+        } elseif {$expgui(MacroRunning) && !$expgui(ShowGENLES)} {
+            append cmd " \" [file join $expgui(gsasexe) $prog] $expnam \" "
         } else {
             if {$cmd != ""} {append cmd "\;"}
@@ -1398 +1411 @@
         }
     }
-    forknewterm "$prog -- $expnam" $cmd [expr !$concurrent] 1
+    if {$expgui(MacroRunning) && !$expgui(ShowGENLES)} {
+        set outfile ${expnam}_macout.LST
+        runnoterm $cmd $outfile
+    } else {
+        forknewterm "$prog -- $expnam" $cmd [expr !$concurrent] 1
+    }
     # load the changed .EXP file automatically?
     if {$expgui(autoexpload)} {
         # load the revised exp file
         loadexp $expgui(expfile)
+    }
+    if {$expgui(MacroRunning)} {
+        if {[file exists  abort_${expnam}_macro.flag]} {
+            file delete abort_${expnam}_macro.flag
+            error "User requested to abort the macro"
+        }
+        update idletasks
     }
 }
@@ -2176 +2201 @@
             if {$expgui(useflag_$i) != [histinfo $i use]} {
                 histinfo $i use set $expgui(useflag_$i)
+                RecordMacroEntry "histinfo $i use set $expgui(useflag_$i)" 0
                 incr expgui(changed)
+                RecordMacroEntry "incr expgui(changed)" 0
             }
 #       }
@@ -2464 +2491 @@
             return
         }
-        # N. B. pause is now hard coded in the .BAT file
-        #
         # loop over multiple commands
         foreach cmd $command {
@@ -2493 +2518 @@
                 checklockfile expgui.lck .lock
             }
+
+            # pause is hard coded in the GSASTCL.BAT file
+            if {$expgui(execprompt)} {
+                set script gsastcl.bat
+            } else {
+                set script gsasnowt.bat
+            }
+
             # replace the forward slashes with backward
             regsub -all / $cmd \\ cmd
             if {[info command winutils::shell] != ""} {
-                winutils::shell [file join $expgui(scriptdir) gsastcl.bat] $cmd
+                winutils::shell [file join $expgui(scriptdir) $script] $cmd
             } else {
                 winexec -d [file nativename [pwd]] \
-                    [file join $expgui(scriptdir) gsastcl.bat] $cmd
+                    [file join $expgui(scriptdir) $script] $cmd
+            }
+            if {$expgui(MacroRunning)} {
+                update 
+                update idletasks
             }
             if {$wait} {
@@ -2532 +2569 @@
         }
         # pause is hard coded in the .BAT file
+        if {$expgui(execprompt)} {
+            set script gsastcl.bat
+        } else {
+            set script gsasnowt.bat
+        }
 
         if {$wait} {
@@ -2542 +2584 @@
                 regsub -all / $cmd \\ cmd
                 exec $env(COMSPEC) /c \
-                        "start [file join $expgui(scriptdir) gsastcl.bat] $cmd"
+                        "start [file join $expgui(scriptdir) $script] $cmd"
             }
             file delete -force expgui.lck
@@ -2555 +2597 @@
                 # run in background
                 exec $env(COMSPEC) /c \
-                        "start [file join $expgui(scriptdir) gsastcl.bat] $cmd" &
+                        "start [file join $expgui(scriptdir) $script] $cmd" &
+                if {$expgui(MacroRunning)} {
+                    update 
+                    update idletasks
+                }
             }
         }
@@ -2588 +2634 @@
             set suffix {&}
         }
-        #
-        #if $wait {
+
+        # hold window open after commands finish
+        if {$expgui(execprompt)} {
             append command "\; echo -n Press Enter to continue \; read x"
-        #}
+        }
         if {$wait && $expgui(autoiconify)} {wm iconify .}
         catch {eval exec xterm $termopts -title [list $title] \
                 -e /bin/sh -c [list $command] $suffix} errmsg
         if $expgui(debug) {puts "xterm result = $errmsg"}
+        if {$expgui(MacroRunning)} {
+            update 
+            update idletasks
+        }
         if {$wait} {
             if {$expgui(autoiconify)} {wm deiconify .}
@@ -2602 +2653 @@
         }
     }
+}
+
+# run commands without a terminal window
+proc runnoterm {command outfile} {
+    global env expgui tcl_platform
+    if {$tcl_platform(platform) == "windows"} {
+        # Windows environment variables
+        set env(GSAS) [file nativename $expgui(gsasdir)]
+        # PGPLOT_FONT is needed by PGPLOT
+        set env(PGPLOT_FONT) [file nativename [file join $expgui(gsasdir) pgl grfont.dat]]
+        # this is the number of lines/page in the .LST (etc.) file
+        set env(LENPAGE) 60
+        set pwd [file nativename [pwd]]
+        # loop over multiple commands
+        foreach cmd $command {
+            # replace the forward slashes with backward
+            regsub -all / $cmd \\ cmd
+            exec $cmd >>& $outfile
+            update
+            update idletasks
+        }
+    } else { 
+        # UNIX environment variables
+        set env(GSAS) [file nativename $expgui(gsasdir)]
+        set env(gsas) [file nativename $expgui(gsasdir)]
+        set env(GSASEXE) $expgui(gsasexe)
+        set env(ATOMDATA) [file join $expgui(gsasdir) data atmdata.dat]
+        set env(ATMXSECT) [file join $expgui(gsasdir) data atmxsect.dat]
+        # PGPLOT_DIR is needed by PGPLOT
+        set env(PGPLOT_DIR) [file join $expgui(gsasdir) pgl]
+        # this is the number of lines/page in the .LST (etc.) file
+        set env(LENPAGE) 60
+        foreach cmd $command {
+            catch {eval exec $cmd >>& $outfile} errmsg
+        }
+        update
+        update idletasks
+    }
+    # check for changes in the .EXP file immediately
+    #whenidle
 }
 
@@ -2652 +2743 @@
     }
 }
+
+#-------------------------------------------------------------------------------
+# Macro Recording
+#-------------------------------------------------------------------------------
+set expgui(MacroBufferedCommand) ""
+set expgui(fpMacroFile) ""
+set expgui(MacroFile) ""
+# Turn on/off mode to save commands in MacroFile
+proc SetRecordMacroOnOff {args} {
+    global expgui
+    if {$expgui(RecordMacro)} {
+        set expgui(fpMacroFile) ""
+        set expgui(MacroBufferedCommand) ""
+        while {$expgui(fpMacroFile) == ""} {
+            set expgui(MacroFile) [tk_getSaveFile -initialdir [pwd] \
+                                       -parent . \
+                                       -filetypes {{"EXPGUI Macro file" .expmac}} \
+                                       -defaultextension .expmac  \
+                                       -initialfile EXPGUI.expmac \
+                                       -title "Choose location to save macro"]
+            if {$expgui(MacroFile) == ""} {
+                # respond to cancel
+                set expgui(fpMacroFile) ""
+                set expgui(MacroFile) ""
+                set expgui(RecordMacro) 0
+                return
+            }
+            if {[catch {
+                set expgui(fpMacroFile) [open $expgui(MacroFile) w]
+                puts $expgui(fpMacroFile) "# [clock format [clock seconds] -format %Y-%m-%dT%T]"
+            } errmsg]} {
+                MyMessageBox -parent . -title "Error opening selected file" \
+                    -message "Error opening macro file:\n$errmsg" \
+                    -icon warning -type TryAgain -default tryagain
+                catch {close $expgui(fpMacroFile)}
+                set expgui(fpMacroFile) ""
+                set expgui(MacroFile) ""
+                set expgui(RecordMacro) 0
+            }
+        }
+    } else {
+        if {[string trim $expgui(MacroBufferedCommand)] != ""} {
+            puts $expgui(fpMacroFile) $expgui(MacroBufferedCommand)
+        }
+        catch {close $expgui(fpMacroFile)}
+        set expgui(fpMacroFile) ""
+        set expgui(MacroFile) ""
+        set expgui(MacroBufferedCommand) ""
+    }
+}
+
+# record a command in the Macro File
+proc RecordMacroEntry {command buffer} {
+    global expgui
+    if {! $expgui(RecordMacro)} return
+    # in buffered mode: hold the last command in memory and compare to the
+    # next. If two commands differ only in the final argument, then the 
+    # second command makes the previous redundant so only the latter version
+    # is retained (This will happen when a user types a string into a box). 
+    # When the commands differ, then the previous is written to file
+    # and the next is retained in memory.
+    if {$buffer} {
+        if {[string trim $expgui(MacroBufferedCommand)] == ""} {
+            set expgui(MacroBufferedCommand) $command
+            return
+        }
+        set diff 0
+        # is command a repeat of previous?
+        foreach a $command b $expgui(MacroBufferedCommand) {
+            if {$diff} {
+                # found a difference, other than in the last arg
+                puts $expgui(fpMacroFile) $expgui(MacroBufferedCommand)
+                break
+            }
+            if {$a != $b} {set diff 1}
+        }
+        set expgui(MacroBufferedCommand) $command
+    } else {
+        # no buffering on current command; write the old and new to file.
+        if {[string trim $expgui(MacroBufferedCommand)] != ""} {
+            puts $expgui(fpMacroFile) $expgui(MacroBufferedCommand)
+        }
+        puts $expgui(fpMacroFile) $command
+        set expgui(MacroBufferedCommand) ""
+    }
+}
+
+proc CantRecordMacroEntry {comment} {
+    global expgui
+    if {! $expgui(RecordMacro)} return
+
+    # no buffering on current command; write the old and new to file.
+    if {[string trim $expgui(MacroBufferedCommand)] != ""} {
+        puts $expgui(fpMacroFile) $expgui(MacroBufferedCommand)
+    }
+    puts $expgui(fpMacroFile) "# unrecorded: $comment"
+    set expgui(MacroBufferedCommand) ""
+    MyMessageBox -parent . -title "No command record" \
+        -message "EXPGUI is not able to record this action in the macro file: $comment" \
+        -icon warning
+}
+
+
+# Play back commands in Macro File
+proc ReplayMacroFile {"lineatatime 0"} {
+    global expgui
+    set expnam [file root [file tail $expgui(expfile)]]
+    file delete abort_${expnam}_macro.flag
+    set expgui(MacroRunning) 0
+    set MacroFile [tk_getOpenFile -initialdir [pwd] \
+                       -parent . \
+                       -filetypes {{"EXPGUI Macro file" .expmac} {Everything .*}} \
+                       -defaultextension .expmac  \
+                       -title "Choose location to read macro"]
+    if {$MacroFile == ""} return
+    set expgui(MacroRunning) 1
+    if {$lineatatime} {
+        set expgui(MacroChanged) 0
+        set top1 .macro
+        catch {destroy $top1}
+        toplevel $top1
+        set txt $top1.t
+        grid [text $txt -width 30 -height 20 -yscrollcommand "$top1.s set"] \
+            -column 0 -row 0 -sticky news
+        wm title $top1 "File $MacroFile"
+        grid [scrollbar $top1.s -command "$txt yview"] \
+            -column 1 -row 0 -sticky ns
+        grid [frame $top1.b] -column 0 -columnspan 2 -row 1 -sticky ew
+        grid columnconfig $top1 0 -weight 1
+        grid rowconfig $top1 0 -weight 1
+        grid [button $top1.b.e -text "Execute line" \
+                  -command "MacroExecuteCurrentLine $txt"] \
+            -column 0 -row 0 -sticky w
+        grid columnconfig $top1.b 1 -weight 1
+        grid [button $top1.b.s -text "Save As" -state disabled \
+                  -command "MacroResave $txt"] -column 1 -row 0
+        set expgui(MacroSaveButton) $top1.b.s 
+        grid [button $top1.b.c -text "Close " \
+                  -command "MacroCloseWindow $txt"] -column 2 -row 0
+        $txt delete 0.0 end
+        set fp [open $MacroFile r]
+        $txt insert 0.0 [read $fp]
+        close $fp
+        MacroHighlightText $txt 1
+        # deal with editing in the box
+        $txt configure -undo 1
+        $txt edit modified 0
+        bind $txt <<Modified>> {
+            $expgui(MacroSaveButton) configure -state normal
+            set expgui(MacroChanged) 1
+        }
+    } else {
+        close [open running_${expnam}_macro.flag w]
+        set saveprompt $expgui(execprompt)
+        set saveautold $expgui(autoexpload)
+        set expgui(execprompt) 0
+        set expgui(autoexpload) 1
+        set expnam [file root [file tail $expgui(expfile)]]
+        if {$expgui(MacroRunning) && !$expgui(ShowGENLES)} {
+            set outfile ${expnam}_macout.LST
+            # create an empty file
+            catch {file delete $outfile}
+            close [open $outfile w]
+            # view it with LSTVIEW
+            set outfile ${expnam}_macout
+            exec $::wishshell [file join $expgui(scriptdir) lstview] $outfile &
+        } else {
+            # show status, offer abort with MACROMON
+            exec $::wishshell [file join $expgui(scriptdir) macromon] $expnam &
+        }
+
+        set  expgui(MacroStatus) "starting script"
+        pleasewait "\nrunning macro\n\nStatus:" expgui(MacroStatus) 
+
+        if {[catch {
+            source $MacroFile
+        } errmsg]} {
+            set txt $::errorInfo
+            catch {
+                set fp [open error.txt a]
+                puts $fp "#  [clock format [clock seconds] -format %Y-%m-%dT%T]"
+                puts $fp $txt
+                close $fp
+            }
+            donewait
+            MyMessageBox -parent . -title "Error running Macro file" \
+                -message "Error running macro file:\n$errmsg\n(details in file error.txt)" \
+                -icon error -type OK -default ok
+        } else {
+            donewait
+        }
+        file delete running_${expnam}_macro.flag
+        set expgui(execprompt) $saveprompt
+        set expgui(autoexpload) $saveautold
+        set expgui(MacroRunning) 0
+        # show changes
+        PaintEXPGUIpages
+        # put comment in output file
+        if {$expgui(MacroRunning) && !$expgui(ShowGENLES)} {
+            set outfile ${expnam}_macout.LST
+            set fp [open $outfile a]
+            puts $fp "\n**** Macro ended ****" 
+            close $fp
+        }
+    }
+}
+
+# highlight a line in the Macro file display
+proc MacroHighlightText {txt line} {
+    $txt tag delete next
+    $txt tag add next $line.0 $line.end
+    $txt see $line.0
+    $txt tag configure next -background yellow
+    # tag all text
+    $txt tag delete all
+    $txt tag add all 0.0 end
+    # double-click moves the current line
+    $txt tag bind all <Double-1> "after idle [list MacroDoubleClick $txt]"
+}
+
+# respond to a double click by moving the next line to be executed to 
+# the line where the double click occurred
+proc MacroDoubleClick {txt} {
+    set line [lindex [split [$txt tag ranges sel] "."] 0]
+    MacroHighlightText $txt $line
+}
+
+# respond to Execute button: execute the current line
+# close window after last command
+proc MacroExecuteCurrentLine {txt} {
+    global expgui
+    set linenum [lindex [split [$txt tag ranges next] "."] 0]
+    if {$linenum == ""} {return}
+    set line [$txt get $linenum.0 $linenum.end]
+    # is this continued (ends with \)?
+    while {[string range $line end end] == "\\" } {
+        incr linenum
+        # get rid of trailing backslash
+        set line [string range $line 0 end-1]
+        #append next line
+        append line [$txt get $linenum.0 $linenum.end]
+    }
+     if {[catch $line errmsg]} {
+        MyMessageBox -parent $txt -title "Error on line" \
+            -message "Error on line $linenum:\n$errmsg" \
+            -icon warning -type Continue -default continue
+    }
+    # show changes
+    PaintEXPGUIpages
+    # move forward in macrofile
+    incr linenum
+    MacroHighlightText $txt $linenum
+    set linenum [lindex [split [$txt tag ranges next] "."] 0]
+    # at end?
+    if {$linenum == ""} {MacroCloseWindow $txt}
+}
+
+# Save a modified macro file
+proc MacroResave {txt} {
+    global expgui
+    set MacroFile [tk_getSaveFile -initialdir [pwd] \
+                       -parent $txt \
+                       -filetypes {{"EXPGUI Macro file" .expmac}} \
+                       -defaultextension .expmac  \
+                       -initialfile $expgui(MacroFile) \
+                       -title "Choose location to save macro"]
+    if {[string trim $MacroFile] == ""} {return}
+    if {[catch {
+        set fp [open $MacroFile w]
+        puts $fp [string trim [$txt get 0.0 end]]
+        close $fp
+    } errmsg]} {
+        MyMessageBox -parent $txt -title "Error writing to file" \
+            -message "Error writing macro file:\n$errmsg" \
+            -icon warning -type TryAgain -default tryagain
+        return
+    }
+    set expgui(MacroChanged) 0
+    # gray out the button
+    $expgui(MacroSaveButton) configure -state disabled
+}
+
+# close the window, but provide a chance to save the file first, if modified
+proc MacroCloseWindow {txt} {
+    global expgui
+    if {$expgui(MacroChanged)} {
+        set ans [MyMessageBox -parent $txt -title "Save macro file?" \
+                     -message "Macro file has been changed, do you want to save it?" \
+                     -icon warning -type "Yes No" -default no]
+        if {$ans != "no"} {MacroResave $txt}
+    }
+    set expgui(MacroRunning) 0
+    destroy [winfo toplevel $txt]
+}
+
+# Add a comment to a macro file
+proc AddCommentMacroFile {} {
+    global expgui
+    if {! $expgui(RecordMacro)} return
+    RecordMacroEntry "# [getstring "comment for macro file"]" 0
+}