Changeset 254 for trunk/addcmds.tcl

Timestamp:

Dec 4, 2009 5:02:59 PM (14 years ago)

Author:

toby

Message:

# on 2000/08/04 18:26:37, toby did:
new procs: MakeXformAtomsBox?, XformAtomsCoord?, XformAtomsOcc?, XformAtomsU

EraseAtoms?

above used for global atom changes on phase pane

File:

• trunk/addcmds.tcl (modified) (1 diff, 3 props)

trunk/addcmds.tcl

@@ -853 +853 @@
     file delete exptool.in exptool.out
 }
+
+#----------------------------------------------
+# commands to modify a group of selected atoms |
+#----------------------------------------------
+
+# make the dialog to choose an action
+proc MakeXformAtomsBox {phase} {
+    global expgui expmap
+    set numberList {}
+    set p $expgui(curPhase)
+    foreach AtomIndex $expgui(selectedatomlist) {
+        # get atom number & phase
+        set tuple [lindex $expmap(atomlistboxcontents) $AtomIndex]
+        lappend numberList [lindex $tuple 0]
+    }
+    if {$numberList == ""} return
+    if {[llength $numberList] > 1} {
+        set suffix s
+        set suffixy "ies"
+    } else {
+        set suffix ""
+        set suffixy "y"
+    }
+    set w .global
+    catch {destroy $w}
+    toplevel $w
+    wm title $w "Edit Atomic Parameter -- phase #$phase"
+    # this needs to track by phase
+    grid [label $w.0 \
+            -text "Modifying atom${suffix} [CompressList $numberList] Phase $phase" \
+            -bg yellow -anchor center] -row 0 -column 0 -columnspan 10 \
+            -sticky nsew
+    grid rowconfigure $w 0 -pad 5
+    grid rowconfigure $w 1 -minsize 2
+
+    grid [TitleFrame $w.1 -bd 6 -relief groove -text "Modify coordinates"] \
+            -row 2 -column 0 -columnspan 10 -sticky news
+    set w1 [$w.1 getframe]
+    set row 0
+    foreach v {x y z} {
+        incr row
+        set col -1
+        grid [label $w1.l$v -text "new $v   =   "] -column [incr col] -row $row
+        foreach o {x y z} {
+            grid [entry $w1.e${v}${o} -width 6] -column [incr col] -row $row
+            $w1.e${v}${o} delete 0 end
+            if {$v == $o} {
+                $w1.e${v}${o} insert end "1.0"
+            } else {
+                $w1.e${v}${o} insert end "0."
+            }
+            grid [label $w1.p${v}${o} -text " $o  +  "] \
+                    -column [incr col] -row $row
+        }
+        grid [entry $w1.e${v} -width 6] -column [incr col] -row $row
+        $w1.e${v} delete 0 end
+        $w1.e${v} insert end "0."
+    }
+    grid [button $w1.do -text "Transform Coordinates" \
+            -command "XformAtomsCoord $phase [list $numberList] $w1" \
+            ] -row [incr row] -column 0 -columnspan 10
+
+    grid rowconfigure $w 3 -minsize 5
+    grid [TitleFrame $w.4 -bd 6 -relief groove -text "Modify occupanc${suffixy}"] \
+            -row 4 -column 0 -columnspan 10 -sticky news
+    set w2 [$w.4 getframe]
+    grid [label $w2.1 -text "Occupancy: "] -row 1 -column 0
+    grid [entry $w2.e -width 10] -column 1 -row 1
+    $w2.e delete 0 end
+    $w2.e insert end 1.0
+    grid columnconfigure $w2 2 -weight 1
+    grid [button $w2.do -text "Set Occupanc${suffixy}" \
+            -command "XformAtomsOcc $phase [list $numberList] $w2" \
+            ] -row 2 -column 0 -columnspan 10
+
+    grid rowconfigure $w 5 -minsize 5
+    grid [TitleFrame $w.6 -bd 6 -relief groove \
+            -text "Modify Displacement Parameter$suffix"] \
+            -row 6 -column 0 -columnspan 10 -sticky news
+    set w2 [$w.6 getframe]
+    grid [label $w2.1 -text "Uiso or Uequiv: "] -row 1 -column 0
+    grid [entry $w2.e -width 10] -column 1 -row 1
+    $w2.e delete 0 end
+    $w2.e insert end 0.025
+    grid columnconfigure $w2 2 -weight 1
+    grid [button $w2.do -text "Set U" \
+            -command "XformAtomsU $phase [list $numberList] $w2" \
+            ] -row 2 -column 0 -columnspan 10
+    grid [frame $w2.f] -row 3 -column 0 -columnspan 10
+    grid [button $w2.f.iso -text "Set Isotropic" \
+            -command "XformAtomsU $phase [list $numberList] iso" \
+            ] -row 0 -column 0
+    grid [button $w2.f.aniso -text "Set Anisotropic" \
+            -command "XformAtomsU $phase [list $numberList] aniso" \
+            ] -row 0 -column 1
+
+    grid rowconfigure $w 5 -minsize 5
+    grid [TitleFrame $w.8 -bd 6 -relief groove \
+            -text "Erase Atom$suffix"] \
+            -row 8 -column 0 -columnspan 10 -sticky news
+    set w2 [$w.8 getframe]
+    grid [button $w2.do -text "Erase Atom${suffix}" \
+            -command "EraseAtoms $phase [list $numberList] $w" \
+            ] -row 2 -column 0 -columnspan 10
+
+
+    grid rowconfigure $w 9 -minsize 5
+    grid [frame $w.b] -row 10 -column 0
+    pack [button $w.b.3 -text Close -command "destroy $w"] -side left
+    bind $w <Return> "destroy $w"
+
+    # force the window to stay on top
+    putontop $w
+    focus $w.b.3
+    tkwait window $w
+    afterputontop
+    # if there are selected atoms, reset their display
+    if {[llength $expgui(selectedatomlist)] != 0} editRecord
+}
+
+# transform the coordinates
+proc XformAtomsCoord {phase numberList w1} {
+    global expgui
+    # get the matrix
+    foreach v {x y z} {
+        foreach o {x y z} {
+            set matrix(${v}${o}) [$w1.e${v}${o} get]
+        }
+        set matrix(${v}) [$w1.e${v} get]
+    }
+    foreach atom $numberList {
+        foreach v {x y z} {
+            set $v [atominfo $phase $atom $v]
+        }
+        foreach v {x y z} {
+            set new$v $matrix(${v})
+            foreach o {x y z} {
+                set new$v [expr [set new$v] + $matrix(${v}${o})*[set $o]]
+            }
+            atominfo $phase $atom $v set [set new$v]
+        }
+        incr expgui(changed)
+    }
+    DisplayAllAtoms noreset
+}
+
+# set the occupancies to a single value
+proc XformAtomsOcc {phase numberList w2} {
+    global expgui
+    # get the value
+    set val [$w2.e get]
+    foreach atom $numberList {
+        atominfo $phase $atom frac set $val
+        incr expgui(changed)
+    }
+    DisplayAllAtoms noreset
+}
+
+# transform Uiso or Uij; if anisotropic set Uequiv to Uij
+proc XformAtomsU {phase numberList w2} {
+    global expgui
+    if {$w2 == "iso"} {
+        foreach atom $numberList {
+            if {[atominfo $phase $atom temptype] != "I"} {
+                atominfo $phase $atom temptype set I
+            }
+        }
+    } elseif {$w2 == "aniso"} {
+        foreach atom $numberList {
+            if {[atominfo $phase $atom temptype] == "I"} {
+                atominfo $phase $atom temptype set A
+            }
+        }
+    } else {
+        # get the value
+        set val [$w2.e get]
+        foreach atom $numberList {
+            if {[atominfo $phase $atom temptype] == "I"} {
+                atominfo $phase $atom Uiso set $val
+            } else {
+                atominfo $phase $atom U11 set $val
+                atominfo $phase $atom U22 set $val
+                atominfo $phase $atom U33 set $val
+                atominfo $phase $atom U12 set 0.0
+                atominfo $phase $atom U13 set 0.0
+                atominfo $phase $atom U23 set 0.0
+            }
+            incr expgui(changed)
+        }
+    }
+    DisplayAllAtoms noreset
+}
+
+# confirm and erase atoms
+proc EraseAtoms {phase numberList w2} {
+    global expgui
+    if {[llength $numberList] <= 0} return
+    # make a list of atoms
+    foreach atom $numberList {
+        append atomlist "\n\t$atom  [atominfo $phase $atom label]"
+    }
+    set msg "OK to remove the following [llength $numberList] atoms from phase $phase:$atomlist"
+    set val [MyMessageBox -parent $w2 -type okcancel -icon warning \
+            -default cancel -title "Confirm Erase" -message $msg]
+    if {$val == "ok"} {
+        foreach atom $numberList {
+            EraseAtom $atom $phase
+            incr expgui(changed)
+        }
+        mapexp
+        DisplayAllAtoms
+        destroy $w2
+    }
+}
+