Changeset 1221 for branches/sandbox/gsascmds.tcl

Timestamp:

Sep 21, 2012 5:56:33 PM (11 years ago)

Author:

toby

Message:

more Fourier work; remove warning on R *3* H sg in CIF

File:

• branches/sandbox/gsascmds.tcl (modified) (1 diff)

branches/sandbox/gsascmds.tcl

@@ -3932 +3932 @@
     exit
 }
+
+# Fourier routines
+proc EditFourier {phase} {
+    #is this a valid phase #?
+    if {[lsearch $::expmap(phaselist) $phase] == -1} return
+    # check that all Fourier records are set to the current phase
+    foreach i [listFourier] {
+        set ph [Fourierinfo $i phase]
+        if {$ph != $phase} {Fourierinfo $i phase set $phase}
+    }
+    # for now we will not offer access to section, (dmin, dmax not supported)
+    set typelist {}
+    foreach i [listFourier] {
+        lappend typelist [Fourierinfo $i type]
+    }
+    set histlist [FourierHists $phase]
+    set limits  [getFourierLimits $phase]
+    if {[winfo exists .export]} {
+        set box .export.fourier
+    } else {
+        set box .fourier
+    }
+    catch {destroy $box}
+    toplevel $box
+    wm title $box "Set Fourier Options, phase $phase"
+    grid [frame $box.1] -row 1 -column 1 -rowspan 10
+    grid [frame $box.2] -row 1 -column 2 -rowspan 10
+    grid [frame $box.b] -sticky news -row 11 -column 1 -columnspan 2
+    grid columnconfigure $box.b 0 -weight 1
+    grid columnconfigure $box.b 3 -weight 1
+    grid [button $box.b.1 -text Continue \
+              -command "set ::DXTL(quit) 0; destroy $box" \
+             ] -row 1 -column 1
+    grid [button $box.b.2 -text Quit \
+              -command "set ::DXTL(quit) 1; destroy $box" \
+             ] -row 1 -column 2
+    
+    # map type selection
+    set row 0
+    grid [label $box.1.$row -text "Select map type(s)"] -column 1 -row $row
+    foreach typ {DELF FCLC FOBS 2FDF 3FDF 4FDF PTSN DPTS} lbl {
+        "Difference Fourier" "Fcalc Fourier" "Fobs Fourier" 
+        "2*Fo-Fc Fourier" "3*Fo-2*Fc Fourier" "4*Fo-3*Fc Fourier" "Patterson map" "Delta-F Patterson"\
+        } {
+            incr row
+            grid [ \
+                       checkbutton $box.1.$row -variable ::DXTL($typ) \
+                       -text "$lbl ($typ)" \
+                      ] -column 1 -row $row -sticky w
+            if {[lsearch $typelist $typ] == -1} {
+                set ::DXTL($typ) 0
+            } else {
+                set ::DXTL($typ) 1
+            }
+        }
+    grid [label $box.2.a1 -text "Histogram(s) to be used:\n(last superceeds)"] -column 1 -row 1
+    grid [label $box.2.a2 -textvariable ::DXTL(histlist) -width 20] -column 2 -row 1 -columnspan 2
+    grid [button $box.2.a3 -text Set \
+              -command "SetFourierHists $box"] -column 5 -row 1
+    set ::DXTL(histlist) {}
+    foreach i $histlist {
+        if {$::DXTL(histlist) != ""} {append ::DXTL(histlist) ", "}
+        append ::DXTL(histlist) $i
+    }
+    grid [label $box.2.m1 -text min] -column 2 -row 2
+    grid [label $box.2.m2 -text max] -column 3 -row 2
+    grid [label $box.2.m3 -text "map step\n(A)"] -column 4 -row 2
+    set row 3
+    foreach axis {X Y Z} lim [lrange $limits 1 end] step [lindex $limits 0] {
+        incr row
+        grid [label $box.2.0$axis -text "$axis limits"] -column 1 -row $row -sticky e
+        grid [entry $box.2.min$axis -width 10 -textvariable ::DXTL(min$axis)] -column 2 -row $row
+        grid [entry $box.2.max$axis -width 10 -textvariable ::DXTL(max$axis)] -column 3 -row $row
+        grid [entry $box.2.step$axis -width 10 -textvariable ::DXTL(step$axis)] -column 4 -row $row
+        set ::DXTL(min$axis) [lindex $lim 0]
+        set ::DXTL(max$axis) [lindex $lim 1]
+        set ::DXTL(step$axis) [format "%.4f" [expr {$step + 0.0001}]]
+    }
+    putontop $box
+    tkwait window $box
+    afterputontop
+    if $::DXTL(quit) return
+    delFourier
+    foreach typ {DELF FCLC FOBS 2FDF 3FDF 4FDF PTSN DPTS} {
+        if {$::DXTL($typ)} {
+            addFourier $phase $typ
+        }
+    }
+    if {$::DXTL(histlist) != "<none>"} {
+        FourierHists $phase set [regsub -all "," $::DXTL(histlist) " "]
+    }
+    setFourierLimits $phase \
+        [list $::DXTL(stepX) $::DXTL(stepY) $::DXTL(stepZ)] \
+        [list $::DXTL(minX) $::DXTL(maxX)] \
+        [list $::DXTL(minY) $::DXTL(maxY)] \
+        [list $::DXTL(minZ) $::DXTL(maxZ)]
+    incr ::expgui(changed)
+}
+
+proc SetFourierHists {top} {
+    set box $top.hstsel
+    set ::DXTL(histbox) $box
+    catch {destroy $box}
+    toplevel $box
+    wm title $box "Select Histograms"
+    grid [frame $box.1 -class HistList] -column 1 -row 1 -sticky news
+    grid columnconfigure $box 1 -weight 1
+    grid [frame $box.2] -column 2 -row 1
+    grid [label $box.2.a -text {Select a histogram from the box
+to the left to add it to the 
+histogram list below
+
+(note that reflection intensities 
+from the last histograms in list 
+override earlier ones)
+
+Histogram List:}] \
+    -column 1 -row 1
+    grid [label $box.2.b -textvariable ::DXTL(histlist)] -column 1 -row 2
+    grid [button $box.2.c -text Clear -command ClearFourierHist] \
+        -column 1 -row 3
+    grid [button $box.3 -text Close -command "destroy $box"] \
+        -column 1 -row 3 -columnspan 2
+    MakeHistBox $box.1
+    bind $box.1.lbox <ButtonRelease-1>  {
+        set selhist [$::DXTL(histbox).1.lbox curselection]
+        if {[llength $selhist] != 1} return
+        AddFourierHist [lindex $::expmap(powderlist) $selhist]
+        lappend ::DXTL(histlist)
+        set hist [lindex $::expmap(powderlist) $selhist]
+        $::DXTL(histbox).2.b config -text $hist
+    }
+    sethistlist
+    putontop $box
+    tkwait window $box
+    afterputontop
+}
+
+proc AddFourierHist {num} {
+    if {$::DXTL(histlist) == "<none>"} {
+        set ::DXTL(histlist) {}
+    }
+    if {$::DXTL(histlist) != ""} {append ::DXTL(histlist) ", "}
+    append ::DXTL(histlist) $num
+}
+
+proc ClearFourierHist {} {
+    set ::DXTL(histlist) "<none>"
+}