source: trunk/import_cell.tcl @ 263

# $Id: import_cell.tcl 263 2009-12-04 23:03:08Z toby $

#-------------------------------------------------
# define info used in addcmds.tcl
set description "PowderCell .CEL file"
set extensions .cel
set procname ReadPowderCellFile
#-------------------------------------------------

proc ReadPowderCellFile {filename} {
    set fp [open $filename r]
    set cell {}
    set atomlist {}
    set spg {}
    set sgnum {}
    set setting {}
    set warnlist {
        3 4 5 6 7 8 10 11 12 13 14 16 17 18 19 20 21 22 23 24 25 27 32 34 35
        37 42 43 44 45 47 48 49 50 55 56 58 59 65 66 68 69 70 71 72
    }

    while {[gets $fp line] >= 0} {
        set token [lindex $line 0] 
        switch [string toupper $token] {
            CELL {
                set cell [lrange $line 1 end]
            }
            RGNR {
                set sgnum [lindex $line 1]
                set setting [lindex $line 2]
                if {$setting == ""} {set setting 1}
                close $fp
                global expgui
                set fp [open [file join $expgui(scriptdir) spacegrp.ref] r]
                set spg_alt {}
                while {[gets $fp line] >= 0} {
                    if {$sgnum == [lindex $line 1] && \
                            $setting == [lindex $line 2]} {
                    set spg [lrange $line 8 end]
                        close $fp
                        break
                    } elseif {$sgnum == [lindex $line 1]} {
                        set spg_alt [lrange $line 8 end]
                    }
                }
                break
            }
            default {
                set lbl [lindex $line 0]
                set type [lindex $line 1]
                # if the type is a number, convert it to an element symbol
                catch {set type [lindex {
                    dummy-entry
                    H HE LI BE B C N O F NE NA MG AL SI P S CL AR K CA SC TI V CR MN FE CO
                    NI CU ZN GA GE AS SE BR KR RB SR Y ZR NB MO TC RU RH PD AG CD IN SN SB
                    TE I XE CS BA LA CE PR ND PM SM EU GD TB DY HO ER TM YB LU HF TA W RE
                    OS IR PT AU HG TL PB BI PO AT RN FR RA AC TH PA U NP PU AM CM BK CF 
                } $type]}
                # convert  F-, K+ and  Al3+ to F, K and Al
                regsub {[1-9]*\+} $type {} type    
                regsub {[1-9]*-} $type {} type    
                lappend atomlist "$lbl [lrange $line 2 4] $type"
            }
        }
    }
    # exact spacegroup was not found
    if {$spg == "" && $spg_alt == ""} {
        # how did this happen
        MyMessageBox -parent . -type ok -icon error \
                -message "Error: The space group number ($sgnum) in file $filename is invalid somehow."
    } elseif {$spg == ""} {
        # don't have the correct setting
        MyMessageBox -parent . -type ok -icon warning \
                -message "Wrong setting: The space group setting ($sgnum #$setting) used in $filename does not match that in GSAS.\n\nYou must apply an origin shift to put the setting into Origin 2!"
        set spg $spg_alt
    } elseif {[lsearch $warnlist $sgnum] != -1} {
        MyMessageBox -parent . -type ok -icon warning \
                -message "Be warned!\nThe space group setting ($sgnum #$setting) used in $filename may not match that in GSAS.\nCheck that the coordinates and symmetry match."
    }
    return "[list $spg] [list $cell] [list $atomlist]"
}