source: gsas/win/dist/bootstrap.bat @ 1196

@REM this script must be run from the GSAS installation directory
@echo ***********************************************************
@echo Please enter proxy server information, if required for your 
@echo web environment. Note that the proxy address will be a 
@echo computer address (proxy.mysite.com) and the proxy port will 
@echo number, such as 80. If not needed or unsure, leave the 
@echo next two responses blank. 
@echo ***********************************************************
@if exist proxyinfo.txt del proxyinfo.txt
@set proxy=
@set proxp=
@set proxadd=
@set /p proxadd="Enter the proxy address [none needed]: "
@if (%proxadd%) == () goto start
@set /p prxport="Enter the proxy port [8080]: "
@if (%prxport%) == () set prxport=8080
@echo %proxadd% > proxyinfo.txt
@echo %prxport% >> proxyinfo.txt
@set proxy=--config-option servers:global:http-proxy-host=%proxadd%
@set proxp=--config-option servers:global:http-proxy-port=%prxport%
@echo Using proxy settings:
@set proxy
@set proxp
:start
@echo *****************************************
@echo Press return to start GSAS/EXPGUI install
@echo *****************************************
@pause
@REM do on initial install
@mkdir MyWork
@ECHO Loading GSAS from subversion server
.\svn\bin\svn co https://subversion.xor.aps.anl.gov/EXPGUI/gsas/all . %proxy% %proxp%
@if exist expgui goto getexpgui
@ECHO *************************************************************************
@ECHO                                 Install failed!
@ECHO *************************************************************************
@ECHO Load from repository failed. Perhaps internet access is blocked or down.
@echo Please check with your network provider if a proxy is needed or verify
@echo your proxy settings.
@ECHO *************************************************************************
@pause
@exit
:getexpgui
@echo loading EXPGUI from repository
.\svn\bin\svn switch https://subversion.xor.aps.anl.gov/EXPGUI/trunk/ expgui %proxy% %proxp%
@echo loading GSAS programs
.\svn\bin\svn switch https://subversion.xor.aps.anl.gov/EXPGUI/gsas/win/exe/ exe %proxy% %proxp%
@echo loading pgplot
.\svn\bin\svn switch https://subversion.xor.aps.anl.gov/EXPGUI/gsas/win/pgl/ pgl %proxy% %proxp%
@echo **************************************************
@echo Install has completed. EXPGUI will now be started.
@echo **************************************************
@pause
%COMSPEC% /c "start exe\ncnrpack.exe expgui\expgui"
exit