source: gsas/all/expgui_applescript.txt @ 938

(*   by F. Farges; farges@univ-mlv.fr ;  changes by B. Toby brian.toby@nist.gov
     based on various AppleScripts for X11
         
         It can launch expgui by double clicking or by dropping a data file  or folder over that app.
*)


(*
--------------------------------------------
Define subroutines  used in later sections of code
--------------------------------------------
*)

(*  get  directory  from a file name *)
on GetParentPath(theFile)
        tell application "Finder" to return container of theFile as text
end GetParentPath

(* find a wish executable or return an error *)
on GetWishExe(myPath)
        set WishExe to myPath & "ncnrpack-osx"
        set WishExe to the POSIX path of WishExe
        tell application "System Events"
                if (file WishExe exists) then
                        return WishExe
                end if
                set WishExe to "/sw/bin/wish"
                if (file WishExe exists) then
                        return WishExe
                end if
                error ("Error: Tcl/Tk executable was not found. See installation instructions.")
        end tell
end GetWishExe

(* test if a file is present and exit with an error message if it is not  *)
on TestFilePresent(appwithpath)
        tell application "System Events"
                if (file appwithpath exists) then
                else
                        error ("Error: file " & appwithpath & " not found. This EXPGUI AppleScript must be run from the gsas directory. Did you move it?")
                end if
        end tell
end TestFilePresent

(* 
--------------------------------------------------------------
this section responds to a double-click. It starts X11 and then expgui, provided 
the expgui script is in the expgui folder of the location of this applescript
 o it finds the location of the current script and finds the expgui 
     tcl script relative to the applescript
 o it finds a version of Tcl/Tk to run either relative to the script location
     or if not present there, in the place where Fink would install it
 o it opens X11 (if needed)
 o it makes X11 active (brings to the front)
 o then it converts the colon-delimited macintosh file location to a POSIX filename
 o for every non-directory file dragged into the icon, it tries to open that file in soffice
-------------------------------------------------------------- 
*)
on run
        set myPath to (path to me)
        set ParentPath to GetParentPath(myPath)
        set appwithpath to ParentPath & "expgui:expgui"
        TestFilePresent(appwithpath)
        set posixapp to quoted form of the POSIX path of appwithpath
        set WishExe to the quoted form of GetWishExe(ParentPath)
        
        tell application "Finder"
                launch application "X11"
        end tell
        
        tell application "X11"
                activate
        end tell
        
        set results to do shell script "cd ~;DISPLAY=:0.0 PATH=$PATH:/usr/local/bin:/usr/X11R6/bin " & WishExe & " " & posixapp & "  > /dev/null 2>&1 &"
end run

(*
----------------------------------------------------------------------
this section handles opening files dragged into the AppleScript
 o it finds the location of the current script and finds the expgui 
     tcl script relative to the applescript
 o it finds a version of Tcl/Tk to run either relative to the script location
     or if not present there, in the place where Fink would install it
 o it opens X11 (if needed)
 o it goes through the list of files dragged in
 o then it converts the colon-delimited macintosh file location to a POSIX filename
 o for every non-directory file dragged into the icon, it tries to open that file in soffice
-----------------------------------------------------------------------
*)

on open names
        
        set myPath to (path to me)
        set ParentPath to GetParentPath(myPath)
        set appwithpath to GetParentPath(myPath) & "expgui:expgui"
        TestFilePresent(appwithpath)
        set posixapp to the quoted form of the POSIX path of appwithpath
        set WishExe to the quoted form of GetWishExe(ParentPath)
        
        tell application "Finder"
                launch application "X11"
        end tell
        
        set filePath to ""
        repeat with i in names
                set macpath to (i as string)
                if macpath ends with ":" then
                        (* if this is a directory; start EXPGUI in that folder *)
                        set filename to the quoted form of the POSIX path of macpath
                        set results to do shell script "cd " & filename & ";DISPLAY=:0.0 PATH=$PATH:/usr/local/bin:/usr/X11R6/bin " & WishExe & "  " & posixapp & " > /dev/null 2>&1 &"
                else if macpath ends with ".EXP" then
                        (* if this is an experiment file, open it *)
                        set filename to the quoted form of the POSIX path of macpath
                        set results to do shell script "cd ~;DISPLAY=:0.0 PATH=$PATH:/usr/local/bin:/usr/X11R6 " & WishExe & " " & posixapp & " " & filename & " > /dev/null 2>&1 &"
                else
                        display dialog "This is not a valid GSAS Experiment file: " & macpath with icon caution buttons {"OK"}
                end if
        end repeat
end open