source: branches/sandbox/rb.tcl @ 1139

Last change on this file since 1139 was 1139, checked in by lake, 10 years ago
File size: 63.3 KB
Line 
1# test code (package already loaded in expgui)
2lappend auto_path [file dirname [info script]]
3package require La
4
5#============================================================================
6# rigid body EXP editing routines (to move into readexp.tcl)
7# RigidBodyList -- returns a list of the defined rigid body types
8# SetRigidBodyVar -- set variables and damping for rigid body type multipliers
9# ReadRigidBody  -- # of times a body is mapped, scaling factors, var #s & coordinates
10# RigidBodyMappingList - return a list instances where a RB is mapped in phase
11# RigidBodyEnableTLS -- Enable or Disable TLS use for a rigid body mapping
12# RigidBodySetTLS  -- change the TLS values for a rigid body mapping
13# RigidBodySetDamp -- change the damping values for a rigid body mapping
14# RigidBodyVary    -- set refinement variable numbers for a rigid body mapping
15# RigidBodyTLSVary -- set TLS refinement variable nums for a rigid body mapping
16# AddRigidBody -- defines a new rigid body type
17# DeleteRigidBody -- remove a rigid body definition
18# ReplaceRigidBody -- replaces a previous rigid body type
19# ReadRigidBodyMapping  -- get parameters for a rigid body mapping
20# MapRigidBody -- map a rigid body type into a phase
21# EditRigidBodyMapping -- change the parameters in a rigid body mapping
22# UnMapRigidBody --remove a rigid body constraint by removing a RB "instance"
23#----- note that these older routines should not be used ------
24# RigidBodyCount -- returns the number of defined rigid bodies (body types)
25#    use RigidBodyList instead
26# RigidBodyMappingCount -- # of times a rigid body is mapped in phase
27#    use RigidBodyMappingList instead
28#============================================================================
29# returns the number of defined rigid bodies
30proc RigidBodyCount {} {
31    set n [string trim [readexp "RGBD  NRBDS"]]
32    if {$n == ""} {
33        set n 0
34    }
35    return $n
36}
37
38# returns a list of the defined rigid body types
39proc RigidBodyList {} {
40    set n [string trim [readexp "RGBD  NRBDS"]]
41    if {$n == ""} {
42        set n 0
43    }
44    set rblist {}
45    foreach rbnum {1 2 3 4 5 6 7 8 9 10 11 12 13 14 15} {
46        set value $rbnum
47        validint value 2
48        set key "RGBD${value}"
49        if {[existsexp "$key NATR "]} {
50            lappend rblist $rbnum
51        }
52        if {[llength $rblist] == $n} break
53    }
54    return $rblist
55}
56
57# ReadRigidBody provides all information associated with a rigid body type
58#  rbnum is the rigid body type number
59# it returns two items:
60#   the number of times the rigid body is mapped
61#   a list containing an element for each scaling factor in rigid body #rbnum.
62# in each element there are four items:
63#    a multiplier value for the rigid body coordinates
64#    a damping value (0-9) for the refinement of the multiplier
65#    a variable number if the multiplier will be refined
66#    a list of cartesian coordinates coordinates
67# each cartesian coordinate contains 4 items: x,y,z and a label
68#  note that the label is present only when the RB is created in EXPGUI and is
69#  not used in GSAS.
70proc ReadRigidBody {rbnum} {
71    if {[lsearch [RigidBodyList] $rbnum] == -1} {
72        return ""
73    }
74    set value $rbnum
75    validint value 2
76    set key "RGBD${value}"
77    set n [string trim [string range [readexp "$key NATR"] 0 4]]
78    set used [string trim [string range [readexp "$key NBDS"] 0 4]]
79    set nmult [string trim [string range [readexp "$key NSMP"] 0 4]]
80    set out {}
81    for {set i 1} {$i <= $nmult} {incr i} {
82        set line [readexp "${key}${i}PARM"]
83        set mult [string trim [string range $line 0 9]]
84        set var [string trim [string range $line 10 14]]
85        set damp [string trim [string range $line 15 19]]
86        set coordlist {}
87        for {set j 1} {$j <= $n} {incr j} {
88            set value $j
89            validint value 3
90            set line [readexp "${key}${i}SC$value"]
91            set x [string trim [string range $line 0 9]]
92            set y [string trim [string range $line 10 19]]
93            set z [string trim [string range $line 20 29]]
94            set lbl [string trim [string range $line 30 39]]
95            lappend coordlist [list $x $y $z $lbl]
96        }
97        lappend out [list $mult $damp $var $coordlist]
98    }
99    return [list $used $out]
100}
101
102# SetRigidBodyVar
103#   rbnum is the rigid body type number
104#   varnumlist is a list of variable numbers
105#      note that if this list is shorter than the number of actual multipliers
106#      for the body, the unspecified variable will not be changed
107#   damplist   is a list of damping values (0-9)
108#      note that if the damplist is shorter than the number of actual multipliers
109#      the unspecified values are not changed
110#  SetRigidBodVar 2 {1 2 3} {}
111#       will vary the (first 3) translations in body #3 and will not change the
112#       damping values
113#  SetRigidBodVar 3 {} {0 0 0}
114#       will not change variable settings but will change the (first 3) damping values
115#  SetRigidBodVar 4 {11 11} {8 8}
116#      changes both variable numbers and damping at the same time
117# Nothing is returned
118proc SetRigidBodyVar {rbnum varnumlist damplist} {
119    if {[lsearch [RigidBodyList] $rbnum] == -1} {
120        return ""
121    }
122    set value $rbnum
123    validint value 2
124    set key "RGBD${value}"
125    set nmult [string trim [string range [readexp "$key NSMP"] 0 4]]
126    for {set i 1} {$i <= $nmult} {incr i} {
127        set j $i
128        incr j -1
129        set var [lindex $varnumlist $j]
130        if {$var != ""} {
131            validint var 5
132            setexp "${key}${i}PARM" $var 11 15
133        }
134        set damp [lindex $damplist $j]
135        if {$damp != ""} {
136            if {$damp > 9} {set damp 9}
137            if {$damp < 0} {set damp 0}
138            validint damp 5
139        }
140        setexp "${key}${i}PARM" $damp 16 20
141    }
142}
143
144
145# return the number of times rigid body $bodytyp is mapped in phase $phase
146proc RigidBodyMappingCount {phase bodytyp} {
147    set key "RGBD[ToHex $phase 1][ToHex $bodytyp 1]"
148    if {! [existsexp "$key  NBDS"]} {return 0}
149    set n [string trim [readexp "$key  NBDS"]]
150    if {$n == ""} {
151        set n 0
152    }
153    return $n
154}
155# return a list of the instances where rigid body $bodytyp is mapped in phase $phase
156proc RigidBodyMappingList {phase bodytyp} {
157    set key "RGBD[ToHex $phase 1][ToHex $bodytyp 1]"
158    if {! [existsexp "$key  NBDS"]} {return {}}
159    set n [string trim [readexp "$key  NBDS"]]
160    if {$n == ""} {
161        set n 0
162    }
163    set rblist {}
164    foreach rbnum {1 2 3 4 5 6 7 8 9 10 11 12 13 14 15} {
165        set value $rbnum
166        validint value 2
167        set key "RGBD[ToHex $phase 1][ToHex $bodytyp 1][ToHex $rbnum 1]"
168        if {[existsexp "$key  NDA"]} {
169            lappend rblist $rbnum
170        }
171        if {[llength $rblist] == $n} break
172    }
173    return $rblist
174}
175
176
177
178# reads rigid body mapping parameters for phase ($phase), body type # ($bodytyp) and instance # ($num)
179# returns a list of items (most lists) as follows:
180#   1) sequence # of first atom in body
181#   2) origin of body in fractional coordinates (3 elements)
182#   3) Euler angles as 6 pairs of numbers (see below)
183#   4) variable numbers for the 9 position variables (origin followed by rotations)
184#   5) damping vals for the 9 position variables (origin followed by rotations)
185#   6) the TLS values, in order below (empty list if TLS is not in use)
186#   7) the variable numbers for each TLS values, in order below (or empty)
187#   8) three damping values for the T, L and S terms.
188# returns an empty list if no such body exists.
189#
190# Euler angles are a list of axes and angles to rotate:
191#   { {axis1 angle1} {axis2 angle2} ...}
192# where axis1,... can be 1, 2 or 3 corresponding to the cartesian X, Y or Z axes
193#
194# The 20 TLS terms are ordered:
195#    T11, T22, T33, T12, T13, T23
196#    L11, L22, L33, L12, L13, L23
197#    S12, S13, S21, S23, S31, S32, SAA, SBB
198#
199proc ReadRigidBodyMapping {phase bodytyp num} {
200    if {[lsearch [RigidBodyMappingList $phase $bodytyp] $num] == -1} {
201        return ""
202    }
203    set key "RGBD[ToHex $phase 1][ToHex $bodytyp 1][ToHex $num 1]"
204    set first [string trim [string range [readexp "$key  NDA"] 0 4]]
205    set line [readexp "$key BDFL"]
206    set varlist {}
207    set damplist {}
208    foreach i {0 1 2 3 4 5 6 7 8} {
209        lappend varlist [string trim [string range $line [expr {5*$i}] [expr {4 + 5*$i}] ]]
210        lappend damplist [string trim [string range $line [expr {45 + $i}] [expr {45 + $i}] ]]
211    }
212    set TLSdamplist {}
213    foreach i {54 55 56} {
214        lappend TLSdamplist [string trim [string range $line $i $i ]]
215    }
216    set line [readexp "${key} BDLC"]
217    set x [string trim [string range $line 0 9]]
218    set y [string trim [string range $line 10 19]]
219    set z [string trim [string range $line 20 29]]
220    set origin [list $x $y $z]
221    set line [readexp "${key} BDOR"]
222    set rotations {}
223    foreach i {0 10 20 30 40 50} {
224        set angle [string trim [string range $line $i [expr {$i+7}]]]
225        set axis [string trim [string range $line [expr {$i+8}] [expr {$i+9}]]]
226        lappend rotations [list $angle $axis]
227    }
228    set TLS [string trim [string range [readexp "${key} LSTF"] 0 4]]
229    set tlsvars {}
230    set tlsvals {}
231    if {$TLS != 0} {
232        set line [readexp "${key}TLSF1"]
233        for {set j 0} {$j < 20} {incr j} {
234            set var [string trim [string range $line [expr {3*$j}] [expr {3*$j+2}]]]
235            if {$var == ""} {set var 0}
236            lappend tlsvars $var
237        }
238        for {set j 0} {$j < 20} {incr j} {
239            set i 0
240            if {$j == 0} {
241                set i 1
242            } elseif {$j == 8} {
243                set i 2
244            } elseif {$j == 16} {
245                set i 3
246            }
247            if {$i != 0} {
248                set line [readexp "${key}TLSP$i"]
249                set i 0
250                set j1 0
251                set j2 7
252            } else {
253                incr j1 8
254                incr j2 8
255            }
256            set val [string trim [string range $line $j1 $j2]]
257            if {$val == ""} {set val 0}
258            lappend tlsvals $val
259        }
260    }
261    return [list $first $origin $rotations $varlist $damplist $tlsvals $tlsvars $TLSdamplist]
262}
263
264# Control TLS representation for phase, body # and instance number of a Rigid body mapping
265#   for mapping with phase ($phase), body type # ($bodytyp) and instance # ($num)
266# Enable TLS use if TLS is non-zero (true). Disable if zero
267proc RigidBodyEnableTLS {phase bodytyp num TLS} {
268    if {[lsearch [RigidBodyMappingList $phase $bodytyp] $num] == -1} {
269        return ""
270    }
271    set key "RGBD[ToHex $phase 1][ToHex $bodytyp 1][ToHex $num 1]"
272    if {$TLS} {
273        setexp "${key} LSTF" [format "%5d" 1] 1 5
274        if {![existsexp "${key}TLSF1"]} {makeexprec "${key}TLSF1"}
275        if {![existsexp "${key}TLSP1"]} {
276            makeexprec "${key}TLSP1"
277            set str {}
278            foreach v {.01 .01 .01 0 0 0 0 0} d {4 4 4 4 4 4 2 2} {
279                validreal v 8 $d
280                append str $v
281            }
282            setexp "${key}TLSP1" $str 1 64
283        }
284        if {![existsexp "${key}TLSP2"]} {
285            makeexprec "${key}TLSP2"
286            set str {}
287            set v 0
288            foreach d {2 2 2 2 4 4 4 4} {
289                validreal v 8 $d
290                append str $v
291            }
292            setexp "${key}TLSP2" $str 1 64
293        }
294        if {![existsexp "${key}TLSP3"]} {
295            makeexprec "${key}TLSP3"
296            set str {}
297            set v 0
298            foreach d {4 4 4 4} {
299                validreal v 8 $d
300                append str $v
301            }
302            setexp "${key}TLSP3" $str 1 64
303        }
304    } else {
305        setexp "${key} LSTF" [format "%5d" 0] 1 5
306    }
307    return 1
308}
309
310# Control the TLS values for Rigid body mapping for mapping with
311#    phase ($phase), body type # ($bodytyp) and instance # ($num)
312# set the 20 TLS values to the values in TLSvals
313# There must be exactly 20 TLS terms, which are ordered:
314#    T11, T22, T33, T12, T13, T23
315#    L11, L22, L33, L12, L13, L23
316#    S12, S13, S21, S23, S31, S32, SAA, SBB
317proc RigidBodySetTLS {phase bodytyp num TLSvals} {
318    if {[lsearch [RigidBodyMappingList $phase $bodytyp] $num] == -1} {
319        return ""
320    }
321    if {[llength $TLSvals] != 20} {return ""}
322    set key "RGBD[ToHex $phase 1][ToHex $bodytyp 1][ToHex $num 1]"
323    set TLS [string trim [string range [readexp "${key} LSTF"] 0 4]]
324    if {$TLS == 0} {return ""}
325    if {![existsexp "${key}TLSF1"]} {makeexprec "${key}TLSF1"}
326    foreach n {1 2 3} {
327        if {![existsexp "${key}TLSP$n"]} {makeexprec "${key}TLSP$n"}
328    }
329    set str {}
330    set n 1
331    set i 0
332    foreach v $TLSvals d {4 4 4 4 4 4 2 2 2 2 2 2 4 4 4 4 4 4 4 4} {
333        incr i
334        validreal v 8 $d
335        append str $v
336        if {$i == 8} {
337            set i 0
338            setexp "${key}TLSP$n" $str 1 64
339            incr n
340            set str {}
341        }
342    }
343    setexp "${key}TLSP$n" $str 1 64
344    return 1
345}
346
347# set damping values for a Rigid body mapping
348#   for mapping with phase ($phase), body type # ($bodytyp) and instance # ($num)
349# there must be 9 damping values in RBdamp for the 9 position variables (origin followed by rotations)
350# Use of TLSdamp is optional, but to be used, TLS representation must be enabled and there must be
351# three damping terms (for all T terms; for all L terms and for all S terms)
352proc RigidBodySetDamp {phase bodytyp num RBdamp "TLSdamp {}"} {
353    if {[lsearch [RigidBodyMappingList $phase $bodytyp] $num] == -1} {
354        return ""
355    }
356    set key "RGBD[ToHex $phase 1][ToHex $bodytyp 1][ToHex $num 1]"
357    if {[llength $RBdamp] != 9} {return ""}
358    set str {}
359    foreach v $RBdamp {
360        if {[validint v 1] != 1} {set v " "}
361        append str $v
362    }
363    setexp "$key BDFL" $str 46 9
364    set TLS [string trim [string range [readexp "${key} LSTF"] 0 4]]
365    if {$TLS != 0 &&  [llength $TLSdamp] == 3} {
366        set str {}
367        foreach v $TLSdamp {
368        if {[validint v 1] != 1} {set v " "}
369            append str $v
370        }
371        setexp "$key BDFL" $str 55 3
372    }
373    return 1
374}
375
376# set refinement variable numbers for a Rigid body mapping
377#   for mapping with phase ($phase), body type # ($bodytyp) and instance # ($num)
378# there must be 9 variable values in RBvar for the 9 position variables (origin followed by rotations)
379# note that the variable values should be unique integers
380proc RigidBodyVary {phase bodytyp num RBvar} {
381    if {[lsearch [RigidBodyMappingList $phase $bodytyp] $num] == -1} {
382        return ""
383    }
384    set key "RGBD[ToHex $phase 1][ToHex $bodytyp 1][ToHex $num 1]"
385    if {[llength $RBvar] != 9} {return ""}
386    set str {}
387    foreach v $RBvar {
388        if {[validint v 5] != 1} {set v " "}
389        append str $v
390    }
391    setexp "$key BDFL" $str 1 45   
392}
393
394# set TLS refinement variable numbers for a Rigid body mapping
395#   for mapping with phase ($phase), body type # ($bodytyp) and instance # ($num)
396# there must be 20 variable values in TLSvar for the 20 parameters:
397#    T11, T22, T33, T12, T13, T23
398#    L11, L22, L33, L12, L13, L23
399#    S12, S13, S21, S23, S31, S32, SAA, SBB
400# note that the variable values should be unique integers
401proc RigidBodyTLSVary {phase bodytyp num TLSvar} {
402    if {[lsearch [RigidBodyMappingList $phase $bodytyp] $num] == -1} {
403        return ""
404    }
405    set key "RGBD[ToHex $phase 1][ToHex $bodytyp 1][ToHex $num 1]"
406    if {[llength $TLSvar] != 20} {return ""}
407    set TLS [string trim [string range [readexp "${key} LSTF"] 0 4]]
408    if {$TLS == 0} {return ""}
409    set str {}
410    foreach v $TLSvar {
411        if {[validint v 3] != 1} {set v " "}
412        append str $v
413    }
414    setexp "${key}TLSF1" $str 1 60
415
416# AddRigidBody: add a new rigid body definition into the .EXP file
417# arguments are:
418#   multlist: defines a list of multipliers for each set of coordinates. In the
419#             simplest case this will be {1}
420#   coordlist: a nested list of coordinates such as { { {0 0 0} {.1 .1 .1} {.2 .2 .2} } }
421# note that when the length of multlist > 1 then coordlist must have the same length.
422# for input where
423#     multlist = {s1 s2} and
424#     coordlist = { { {0 0 0} {1 1 0} {.0 .0 .0} ...}
425#                     {0 0 0} {1 1 0} {2 1 2} ...}
426#                 }
427# the cartesian coordinates are defined from the input as
428#    atom 1 = s1 * (0,0,0) + s2*(0,0,0) [ = (0,0,0)]
429#    atom 2 = s1 * (1,1,0) + s2*(1,1,0) [ = (s1+s2) * (1,1,0)]
430#    atom 3 = s1 * (0,0,0) + s2*(2,1,2) [ = s2 * (2,1,2)]
431#    ...
432# Returns the number of the rigid body that has been created
433proc AddRigidBody {multlist coordlist} {
434    # find the first unused body #
435    foreach rbnum {1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16} {
436        set value $rbnum
437        validint value 2
438        set key "RGBD${value}"
439        if {! [existsexp "$key NATR "]} {break}
440    }
441    # did we go too far?
442    if {$rbnum == 16} {return ""}
443    # increment the RB counter
444    set n [string trim [readexp "RGBD  NRBDS"]]
445    if {$n == ""} {
446        makeexprec "RGBD  NRBDS"
447        set n 0
448    }
449    incr n
450    validint n 5
451    setexp "RGBD  NRBDS" $n 1 5
452    SetRigidBody $rbnum $multlist $coordlist
453    return $rbnum
454}
455
456# DeleteRigidBody: remove a rigid body definition from the .EXP file
457# The body may not be mapped. I am not sure if GSAS allows more than 9 bodies,
458# but if it does, the simplifed approach used here will fail, so this
459# is not allowed.
460# Input:
461#   Rigid body number
462# Returns:
463#   1 on success
464#   -1 if the body number is 11 or greater
465#   -2 if the body is mapped
466#   -3 if the body is not defined
467proc DeleteRigidBody {rbnum} {
468    # can't delete bodies with numbers higher than 10, since the key prefix
469    # (RGBD11... will overlap with rigid body instance records, which would be
470    # deleted below
471    if {$rbnum > 10} {
472        return -1
473    }
474    set value $rbnum
475    validint value 2
476    set key "RGBD${value}"
477    if {![existsexp "$key NATR "]} {
478        return -2
479    }
480    # make sure the body is not mapped
481    if {[string trim [string range [readexp "$key NBDS"] 0 4]] != 0} {
482        return -3
483    }
484    # delete the records starting with "RGBD x" or "RGBD10"
485    foreach key [array names ::exparray "${key}*"] {
486        #puts $key
487        delexp $key
488    }
489    # decrement the RB counter
490    set n [string trim [readexp "RGBD  NRBDS"]]
491    if {$n == ""} {
492        set n 0
493    }
494    incr n -1
495    validint n 5
496    if {$n > 0} {
497        setexp "RGBD  NRBDS" $n 1 5
498    } else {
499        delexp "RGBD  NRBDS"
500    }
501    return 1
502}
503
504# ReplaceRigidBody: replace all the information for rigid body #rbnum
505# Works the sames as AddRigidBody (see above) except that the rigid body is replaced rather
506# than added.
507# Note that count of the # of times the body is used is preserved
508proc ReplaceRigidBody {rbnum multlist coordlist {varlist ""} {damplist ""}} {
509    set value $rbnum
510    validint value 2
511    set key "RGBD${value}"
512    set line [readexp "$key NBDS"]
513    foreach key [array names ::exparray "${key}*"] {
514        #puts $key
515        delexp $key
516    }
517    SetRigidBody $rbnum $multlist $coordlist $varlist $damplist
518    setexp "$key NBDS" $line 1 68
519}
520
521# Edit the parameters for rigid body #rbnum
522# (normally called from ReplaceRigidBody or AddRigidBody)
523proc SetRigidBody {rbnum multlist coordlist {varlist ""} {damplist ""}} {
524    set value $rbnum
525    validint value 2
526    set key "RGBD${value}"
527    # number of atoms
528    set value [llength [lindex $coordlist 0]]
529    validint value 5
530    makeexprec "$key NATR"
531    setexp "$key NATR" $value 1 5
532    # number of times used
533    set value 0
534    validint value 5
535    makeexprec "$key NBDS"
536    setexp "$key NBDS" $value 1 5
537    # number of coordinate matrices
538    set value [llength $multlist]
539    validint value 5
540    makeexprec "$key NSMP"
541    setexp "$key NSMP" $value 1 5
542    set i 0
543    foreach mult $multlist coords $coordlist {
544        set var [lindex $varlist $i]
545        if {$var == ""} {set var 0}
546        set damp [lindex $damplist $i]
547        if {$damp == ""} {set damp 0}
548        incr i
549        makeexprec "${key}${i}PARM"
550        setexp "${key}${i}PARM" [format "%10.5f%5d%5d" $mult $var $damp] 1 20
551        set j 0
552        foreach item $coords {
553            #puts $item
554            incr j
555            set value $j
556            validint value 3
557            makeexprec "${key}${i}SC$value"
558            if {[llength $item] == 4} {
559                setexp "${key}${i}SC$value" [eval format "%10.6f%10.6f%10.6f%10s" $item] 1 40
560            } elseif {[llength $item] == 3} {
561                setexp "${key}${i}SC$value" [eval format "%10.6f%10.6f%10.6f" $item] 1 30
562            } else {
563                return -code 3 "Invalid number of coordinates"
564            }
565        }
566    }
567}
568
569# convert a decimal to the GSAS hex encoding with a field $digits long.
570proc ToHex {num digits} {
571    return [string toupper [format "%${digits}x" $num]]
572}
573
574# convert a GSAS hex encoding to a decimal integer
575proc FromHex {hex} {
576    return [scan $hex "%x"]
577}
578
579# MapRigidBody: define an "instance" of a rigid body: meaning that the coordinates
580# (and optionally U values) for a set of atoms will be generated from the rigid body
581# arguments:
582#   phase: phase number (1-9)
583#   bodytyp: number of rigid body (1-15) as returned from AddRigidBody
584#   firstatom: sequence number of the first atom in phase (note that atoms may
585#              not be numbered sequentially)
586#   position: list of three fractional coordinates for the origin of the rigid body coordinates
587#   angles: list of 3 angles to rotate the rigid body coordinates around x, y, z of the
588#           cartesian system before the body is translated to position.
589# returns the instance # (number of times body $bodytyp has been used in phase $phase)
590proc MapRigidBody {phase bodytyp firstatom position angles} {
591    # find the first unused body # for this phase & type
592    foreach rbnum {1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16} {
593        set key "RGBD[ToHex $phase 1][ToHex $bodytyp 1][ToHex $rbnum 1]"
594        if {! [existsexp "$key  NDA"]} {break}
595    }
596    # did we go too far?
597    if {$rbnum == 16} {return ""}
598    # increment number of mapped bodies of this type overall
599    set value $bodytyp
600    validint value 2
601    set key "RGBD${value}"
602    set used [string trim [string range [readexp "$key NBDS"] 0 4]]
603    incr used
604    set value $used
605    validint value 5
606    setexp "$key NBDS" $value 1 5
607    # increment number of mapped bodies of this type in this phase
608    set key "RGBD[ToHex $phase 1][ToHex $bodytyp 1]"
609    if {[existsexp "$key  NBDS"]} {
610        set used [string trim [string range [readexp "$key  NBDS"] 0 4]]
611    } else {
612        makeexprec "$key  NBDS"
613        set used 0
614    }
615    incr used
616    set value $used
617    validint value 5
618    setexp "$key  NBDS" $value 1 5
619    # now write the mapping parameters
620    set key "RGBD[ToHex $phase 1][ToHex $bodytyp 1][ToHex $rbnum 1]"
621    set value $firstatom
622    validint value 5
623    makeexprec "$key  NDA"
624    setexp "$key  NDA" $value 1 5
625    set l1 {}
626    set l2 {}
627    for {set i 0} {$i < 9} {incr i} {
628        append l1 [format %5d 0]
629        append l2 [format %1d 0]
630    }
631    makeexprec "$key BDFL"
632    setexp "$key BDFL" $l1$l2 1 54
633    makeexprec "${key} BDLC"
634    setexp "${key} BDLC" [eval format "%10.6f%10.6f%10.6f" $position] 1 30
635    makeexprec "${key} BDOR"
636    set l1 {}
637    foreach val "$angles 0 0 0" dir "1 2 3 1 1 1" {
638        append l1 [format "%8.2f%2d" $val $dir]
639    }
640    setexp "${key} BDOR" $l1 1 60
641    makeexprec "${key} LSTF"
642    setexp "${key} LSTF" [format "%5d" 0] 1 5
643    return $rbnum
644}
645
646# EditRigidBodyMapping: edit parameters that define an "instance" of a rigid body (see MapRigidBody)
647# arguments:
648#   phase: phase number (1-9)
649#   bodytyp: number of rigid body (1-15) as returned from AddRigidBody
650#   bodynum: instance number, as returned by MapRigidBody
651#   position: list of three fractional coordinates for the origin of the rigid body coordinates
652#   angles: list of 3 angles to rotate the rigid body coordinates around x, y, z of the
653#           cartesian system before the body is translated to position.
654#
655proc EditRigidBodyMapping {phase bodytyp bodynum position angles} {
656    # number of bodies of this type in this phase
657    set key "RGBD[ToHex $phase 1][ToHex $bodytyp 1][ToHex $bodynum 1]"
658    setexp "${key} BDLC" [eval format "%10.6f%10.6f%10.6f" $position] 1 30
659    set l1 {}
660    foreach val "$angles 0 0 0" dir "1 2 3 1 1 1" {
661        append l1 [format "%8.2f%2d" $val $dir]
662    }
663    setexp "${key} BDOR" $l1 1 60
664}
665
666# UnMapRigidBody: remove a rigid body constraint by removing a RB "instance"
667# (undoes MapRigidBody)
668# arguments:
669#   phase: phase number (1-9)
670#   bodytyp: number of rigid body (1-15) as returned from AddRigidBody
671#   bodynum: instance number, as returned by MapRigidBody
672proc UnMapRigidBody {phase bodytyp mapnum} {
673    if {[lsearch [RigidBodyMappingList $phase $bodytyp] $mapnum] == -1} {
674        return ""
675    }
676    # decrement number of mapped bodies of this type overall
677    set value $bodytyp
678    validint value 2
679    set key "RGBD${value}"
680    set used [string trim [string range [readexp "$key NBDS"] 0 4]]
681    incr used -1
682    set value $used
683    validint value 5
684    setexp "$key NBDS" $value 1 5
685    # decrement number of mapped bodies of this type in this phase
686    set key "RGBD[ToHex $phase 1][ToHex $bodytyp 1]"
687    if {[existsexp "$key  NBDS"]} {
688        set used [string trim [string range [readexp "$key  NBDS"] 0 4]]
689    } else {
690        set used 0
691    }
692    incr used -1
693    set value $used
694    validint value 5
695    if {$used > 0} {
696        setexp "$key  NBDS" $value 1 5
697    } else {
698        delexp "$key  NBDS"
699    }
700    # now delete the mapping parameter records
701    set key "RGBD[ToHex $phase 1][ToHex $bodytyp 1][ToHex $mapnum 1]"
702    foreach key [array names ::exparray "${key}*"] {
703        delexp $key
704    }
705    return $used
706}
707
708#============================================================================
709# Rigid body utility routines
710#============================================================================
711# RigidBodyGetVarNums: Returns a list of the variable numbers in use
712#       for rigid body variable parameters.
713# RigidBodyAtomNums: returns a list of atom numbers that are mapped to
714#       rigid bodies in a selected phase
715# RigidStartAtoms: returns a list of atoms that are allowed for creation of RB
716# ExtractRigidBody: Use the GSAS geometry program to cartesian coordinates &
717#       setting info for a RB from fractional coordinates for atoms in a phase
718# RunRecalcRBCoords: updates the coordinates in all phases after changes have
719#       been made to rigid parameters.
720# CalcBody: Convert ortho to fractional coordinates using RB parameters
721# FitBody: Optimize the origin and Euler angles to match a rigid body to a
722#       set of fractional coordinates
723# zmat2coord: convert a z-matrix to a set of cartesian coordinates
724# RB2cart: convert the representation used for rigid bodies into
725#       cartesian coordinates
726# PlotRBtype: plot a rigid body with DRAWxtl
727# PlotRBcoords: plot orthogonal coordinates with DRAWxtl
728# DRAWxtlPlotRBFit: plot a set of fraction coordinates superimposed
729#       on a structure read from a phase with DRAWxtl
730#============================================================================
731#============================================================================
732# RigidBodyGetVarNums: Returns a list of the variable numbers used already
733# for rigid body variable parameters
734proc RigidBodyGetVarNums {} {
735    set varlist {}
736    foreach type [RigidBodyList] {
737        set typelist [lindex [ReadRigidBody $type] 1]
738        foreach item $typelist {
739            lappend varlist [lindex $item 2]
740        }
741        foreach phase $::expmap(phaselist) {
742            foreach i [RigidBodyMappingList $phase $type] {
743                set items [ReadRigidBodyMapping $phase $type $i]
744                set varlist [concat $varlist [lindex $items 3]]
745                if {[llength [lindex $items 6]] > 0} {
746                    set varlist [concat $varlist [lindex $items 6]]
747                }
748            }
749        }
750    }
751    return [lsort -integer -unique $varlist]
752}
753
754# RigidBodyAtomNums: Returns a list of the atoms mapped to rigid bodies in
755# phase $phase
756proc RigidBodyAtomNums {phase} {
757    if {[lsearch $::expmap(phaselist) $phase] == -1} {return ""}
758    set allatoms $::expmap(atomlist_$phase)
759    # get matching atoms coordinate range
760    set mappedlist {}
761    foreach type [RigidBodyList] {
762        foreach i [RigidBodyMappingList $phase $type] {
763            # get the number of atoms in this type of body
764            set natoms [llength [lindex [lindex [lindex [ReadRigidBody $type] 1] 0] 3]]
765            set natom1 [expr {$natoms - 1}]
766            set items [ReadRigidBodyMapping $phase $type $i]
767            set firstatom [lindex $items 0]
768            set firstind [lsearch $allatoms $firstatom]
769            set mappedlist [concat $mappedlist \
770                                [lrange \
771                                     [lrange $allatoms $firstind end] \
772                                     0 $natom1] \
773                               ]
774        }
775    }
776    return [lsort -integer $mappedlist]
777}
778
779# RigidStartAtoms: Find allowed starting atoms for a rigid body in a phase
780# Input:
781#   phase is the phase number
782#   natoms is the number of atoms in the RB to be mapped
783# Returns a list of valid "start" atoms.
784# Example: if the atom numbers in the phase are {2 4 5 6 7 8} and no rigid bodies
785# are mapped, then a 4-atom body can be mapped starting with atom 2, 4 or 5 only,
786# so {2 4 5} is returned
787# If atoms 2-6 were already mapped, then this routine would return an empty
788# list, as it is not possible to map the body.
789proc RigidStartAtoms {phase natoms} {
790    if {[lsearch $::expmap(phaselist) $phase] == -1} {return ""}
791    set allatoms $::expmap(atomlist_$phase)
792    set usedatoms [RigidBodyAtomNums $phase]
793    set startatomlist {}
794    for {set i 0} {$i < [llength $allatoms]} {incr i} {
795        set al [lrange $allatoms $i [expr {$i+$natoms-1}]]
796        if {[llength $al] < $natoms} break
797        set ok 1
798        foreach atom $al {
799            if {[lsearch $usedatoms $atom] != -1} {
800                set ok 0
801                break
802            }
803        }
804        if $ok {lappend startatomlist [lindex $al 0]}
805    }
806    return $startatomlist
807}
808
809# ExtractRigidBody: Use the GSAS geometry program to compute a set of cartesian coordinates for a
810# set of atoms in a .EXP file and provide the origin shift and Euler angles needed to
811# place the cartesian system into the crystal coordinates. Used for setting up a rigid body.
812# Returns a nested list of lists:
813#   element 0: a list of the origin location {x y z} in fraction coordinates
814#   element 1: a list of three rotation angles in form {a1 a2 a3}
815#              where a1, a2 and a3 are rotations around the cartesian x, y and z axes
816#   element 2: a list of $natom cartesian coordinate triples {{x1 y1 z1} {x2 y2 z2}...}
817# arguments:
818    # phase: phase #
819    # natom: number of atoms in group
820    # firstatom: sequence # in phase (may be > than number of the atom)
821    # originlist: atoms to define origin (where 1 is first atom in group; <= natom)
822    # vector1: list of 3 values with X, Y or Z, atom #a and #b (number as in origin)  (for example {X 1 3})
823    # vector2: list of 3 values with X, Y or Z, atom #a and #b (number as in origin)
824    # note that vector2 must define a different axis than vector1
825    # also and vector1 and vector2 cannot use the same atom pair
826proc ExtractRigidBody {phase natom firstatom originlist vector1 vector2} {
827    global expgui
828    set fp [open "geom.inp" "w"]
829    puts $fp "N"
830    if {[llength ::expmap(phaselist)] > 1} {
831       # select phase
832       puts $fp "N"
833       puts $fp $phase
834       puts $fp "N"
835    }
836    puts $fp "R"
837    puts $fp "$natom"
838    puts $fp "$firstatom"
839    puts $fp [llength $originlist]
840    foreach i $originlist {
841        puts $fp $i
842    }
843    foreach i [concat $vector1 $vector2] {
844        puts $fp $i
845    }
846    puts $fp "0"
847    puts $fp "X"
848    close $fp
849    #puts "[file join $expgui(gsasexe) geometry] $expgui(expfile) < geom.inp > geom.out"
850    catch {
851        exec [file join $expgui(gsasexe) geometry] $expgui(expfile) < geom.inp > geom.out
852    } err
853    #puts $err
854    file delete geom.inp
855    set fp [open geom.out r]
856    set origin {}
857    set Euler {}
858    set coordlist {}
859    while {[gets $fp line] >= 0} {
860        if {[string first "Cell coordinates of origin" $line] != -1} {
861            set origin [lrange [string range $line [string first "are" $line] end] 1 3]
862            #puts "origin in rb = $origin"
863        }
864        if {[string first "Rotation angles" $line] != -1} {
865            set Euler {}
866            foreach i [lrange [split $line "="] 1 3] {
867                lappend Euler [lindex $i 0]
868            }
869            #puts $line
870            #puts $Euler
871        }
872        if {[string first "Atom   Orthon" $line] != -1} {
873            set coordlist {}
874            for {set i 1} {$i <= $natom} {incr i} {
875                gets $fp line
876                set coord {}
877                lappend coord [string trim [string range $line 9 15]]
878                lappend coord [string trim [string range $line 16 22]]
879                lappend coord [string trim [string range $line 23 29]]
880                lappend coord [string trim [string range $line 0 8]]
881                #puts $line
882                #puts $coord
883                lappend coordlist $coord
884            }
885            #puts $coordlist
886        }
887    }
888    #file delete geom.out
889    if {[llength $origin] == 0 || [llength $Euler] == 0 || [llength $coordlist] == 0} {
890       puts "Error: run of GEOMETRY failed"
891    }
892    return [list $origin $Euler $coordlist]
893}
894
895# RunRecalcRBCoords: updates the coordinates in a .EXP file after a rigid
896# body has been changed, mapped or the setting info is changed
897proc RunRecalcRBCoords { } {
898    global expgui tcl_platform
899    set input [open resetmult.inp w]
900    puts $input "Y"
901    puts $input "l b"
902    puts $input "n"
903    puts $input "x x x"
904    puts $input "x"
905    close $input
906    # Save the current exp file
907    savearchiveexp
908    # disable the file changed monitor
909    set expgui(expModifiedLast) 0
910    set expnam [file root [file tail $expgui(expfile)]]
911    set err [catch {
912        if {$tcl_platform(platform) == "windows"} {
913            exec [file join $expgui(gsasexe) expedt.exe] $expnam < resetmult.inp >& resetmult.out
914        } else {
915            exec [file join $expgui(gsasexe) expedt] $expnam < resetmult.inp >& resetmult.out
916        }
917    } errmsg]
918    loadexp $expgui(expfile)
919    set fp [open resetmult.out r]
920    set out [read $fp]
921    close $fp
922    set expgui(exptoolout) $out
923    catch {file delete resetmult.inp resetmult.out}
924    if {$err} {
925        return $errmsg
926    } else {
927        return ""
928    }
929}
930
931
932# compute a rotation matrix for orthogonal coordinates (based on MAKMATD in GSAS)
933# rotate angle degrees around axis (1, 2 or 3) for (x, y, or z)
934# returns a list that can be used as a matrix in the La package
935proc RotMatrix {axis angle} {
936    set ang [expr {$angle * acos(0) / 90.}]
937    set mat "1 0 0 0 1 0 0 0 1"
938    if {$axis == 1}  {
939        set i1 1
940        set i2 2
941    } elseif {$axis == 2}  {
942        set i1 2
943        set i2 0
944    } else {
945        set i1 0
946        set i2 1
947    }
948    proc imat {i1 i2} {return [expr {(3*$i2) + $i1}]}
949    foreach item {
950        {$i1 $i1 [expr {cos($ang)}]}
951        {$i2 $i2 [expr {cos($ang)}]}
952        {$i1 $i2 [expr {-sin($ang)}]}
953        {$i2 $i1 [expr {sin($ang)}]}
954    } {
955        foreach {c r val} [subst $item] {}
956        set mat [lreplace $mat [imat $c $r] [imat $c $r] $val] 
957    }
958    return "2 3 3 $mat"
959}
960
961# compute the derivative of the rotation matrix with respect to the angle, see RotMatrix
962# (based on MAKMATD in GSAS)
963# returns a list that can be used as a matrix in the La package
964proc DerivRotMatrix {axis angle} {
965    set ang [expr {$angle * acos(0) / 90.}]
966    set mat "0 0 0 0 0 0 0 0 0"
967    if {$axis == 1}  {
968        set i1 1
969        set i2 2
970    } elseif {$axis == 2}  {
971        set i1 2
972        set i2 0
973    } else {
974        set i1 0
975        set i2 1
976    }
977    proc imat {i1 i2} {return [expr {(3*$i2) + $i1}]}
978    foreach item {
979        {$i1 $i1 [expr {-sin($ang) * acos(0) / 90.}]}
980        {$i2 $i2 [expr {-sin($ang) * acos(0) / 90.}]}
981        {$i1 $i2 [expr {-cos($ang) * acos(0) / 90.}]}
982        {$i2 $i1 [expr {cos($ang) * acos(0) / 90.}]}
983    } {
984        foreach {c r val} [subst $item] {}
985        set mat [lreplace $mat [imat $c $r] [imat $c $r] $val] 
986    }
987    return "2 3 3 $mat"
988}
989
990# compute an orthogonalization matrix from cell parameters (based on AMATRX in GSAS)
991# returns a list that can be used as a matrix in the La package
992proc OrthoMatrix {a b c alpha beta gamma} {
993    set CA [expr {cos($alpha * acos(0) / 90.)}]
994    set CB [expr {cos($beta * acos(0) / 90.)}]
995    set CG [expr {cos($gamma * acos(0) / 90.)}]
996    set SA [expr {sin($alpha * acos(0) / 90.)}]
997    set SB [expr {sin($beta * acos(0) / 90.)}]
998    set SC [expr {sin($gamma * acos(0) / 90.)}]
999    set CASTAR [expr { ($CB*$CG-$CA)/($SB*$SC) }]    ;#! cos(Alpha*)
1000    set CBSTAR [expr { ($CA*$CG-$CB)/($SA*$SC) }]    ;#! cos(Beta*)
1001    set CCSTAR [expr { ($CA*$CB-$CG)/($SA*$SB) }]    ;#! cos(Gamma*)
1002    set SASTAR [expr { sqrt(1.0-($CASTAR*$CASTAR*2)) }]    ;#! sin(Alpha*)
1003    set SBSTAR [expr { sqrt(1.0-($CBSTAR*$CBSTAR*2)) }]    ;#! sin(Beta*)
1004    set SCSTAR [expr { sqrt(1.0-($CCSTAR*$CCSTAR*2)) }]    ;#! sin(Gamma*)
1005
1006    set A  "2 3 3      $a 0 0    0 $b 0    0 0 $c"
1007    set A1 "2 3 3     1.0 0 0    $CG [expr {$SASTAR*$SC}] [expr {-$CASTAR*$SC}]    $CB 0.0 $SB"
1008    #!This matrix is
1009    #!   (1.0      0.0            0.0             )
1010    #!   (cos(G)  sin(A*)*sin(G) -cos(A*)*sin(G)  )
1011    #!   (cos(B)   0.0            sin(B)          )
1012    return [La::transpose [La::mmult $A $A1]]
1013}
1014
1015# compute the transformation matrix that converts a rigid body coordinates into fractional
1016# coordinates
1017# arguments:
1018#   rotations: a list of axes and angles to rotate: { {axis1 angle1} {axis2 angle2} ...}
1019#              where axis1,... can be 1, 2 or 3 corresponding to the cartesian X, Y or Z axes
1020#   cellprms: a list with "a b c alpha beta gamma" in Angstroms and degrees
1021# returns a list that can be used as a matrix in the La package
1022proc CalcXformMatrix {rotations cellprms} {
1023    set prod {}
1024    foreach item $rotations {
1025        #puts $item
1026        set mat [eval RotMatrix $item]
1027        if {$prod == ""} {
1028            set prod $mat
1029        } else {
1030            set prod [La::mmult $prod $mat]
1031        }
1032    }
1033    #puts "--- rotation product ---"
1034    #puts [La::show $prod]
1035
1036    set ortho [eval OrthoMatrix $cellprms]
1037    #puts "--- ortho ---"
1038    #puts [La::show $ortho]
1039    set deortho [La::msolve $ortho [La::mident 3] ]
1040    #puts "--- deortho ---"
1041    #puts [La::show $deortho]
1042    #puts "--- xform ---"
1043    set xform [La::mmult $deortho $prod]
1044    return $xform
1045}
1046
1047# transforms a triplet of orthogonal coordinates into fractional ones using
1048# arguments:
1049#    xform: a transformation matrix from CalcXformMatrix
1050#    origin: a list of fraction coordinates {x y z} describing the location of the
1051#            origin of the orthogonal coordinates in the crystal system
1052#    ortho: a triplet of othogonal coordinates
1053# returns a triplet of fractional coordinates
1054proc Ortho2Xtal {xform origin ortho} {
1055    set ocv "2 3 0 $ortho"
1056    set frac [La::mmult $xform $ocv]
1057    #puts [La::show [La::transpose $frac]]
1058    #puts $frac
1059    set frac [La::madd $frac "[lrange $frac 0 2] $origin"]
1060    #puts [La::show [La::transpose $frac]]
1061    return $frac
1062}
1063
1064# compute the derivative of the transformation matrix (see CalcXformMatrix)
1065# with respect to every rotation in the $rotations list
1066# arguments:
1067#   rotations: a list of axes and angles to rotate: { {axis1 angle1} {axis2 angle2} ...}
1068#              where axis1,... can be 1, 2 or 3 corresponding to the cartesian X, Y or Z axes
1069#   cellprms: a list with "a b c alpha beta gamma" in Angstroms and degrees
1070# returns a list of matrices where each matrix is a list that can be used as a
1071# matrix in the La package
1072proc CalcDerivMatrix {rotations cellprms} {
1073    set ortho [eval OrthoMatrix $cellprms]
1074    set deortho [La::msolve $ortho [La::mident 3] ]
1075    set derivlist {}
1076
1077    foreach item $rotations {
1078        #puts $item
1079        set mat [eval DerivRotMatrix $item]
1080        #puts $item
1081        #puts [La::show $mat]
1082        set xform [La::mmult $deortho $mat]
1083        lappend derivlist $xform
1084    }
1085    return $derivlist
1086}
1087
1088# CalcBody: Calculate fractional coordinates using rigid body setting parameters
1089# arguments:
1090#  Euler: a list of axes and angles to rotate: { {axis1 angle1} {axis2 angle2} ...}
1091#              where axis1,... can be 1, 2 or 3 corresponding to the cartesian X, Y or Z axes
1092#  cell: a list with "a b c alpha beta gamma" in Angstroms and degrees
1093#  ortholist: list containing triplets with orthogonal coordinates
1094#  origin: a list of fraction coordinates {x y z} describing the location of the
1095#            origin of the orthogonal coordinates in the crystal system
1096#     note that the length of ortholist, useflag and fraclist should be the same
1097# Returns a list with the computed fractional coordinates for all atoms
1098proc CalcBody {Euler cell ortholist origin} {
1099    set xform [CalcXformMatrix $Euler $cell]
1100    set i 0
1101    set sumdvs 0
1102    set fracout {}
1103    set rmsout {}
1104    foreach oc $ortholist {
1105        set frac [lrange [Ortho2Xtal $xform $origin $oc] 3 end]
1106        lappend fracout $frac
1107    }
1108    return $fracout
1109}
1110
1111
1112# fit a rigid body's origin
1113# arguments:
1114#  Euler: a list of axes and angles to rotate: { {axis1 angle1} {axis2 angle2} ...}
1115#              where axis1,... can be 1, 2 or 3 corresponding to the cartesian X, Y or Z axes
1116#  cell: a list with "a b c alpha beta gamma" in Angstroms and degrees
1117#  ortholist: list containing triplets with orthogonal coordinates
1118#  useflag: list of flags to indicate if an atom should be used (1) or ignored (0)
1119#  fraclist: list containing triplets with fractional coordinates 
1120#  origin: a list of fraction coordinates {x y z} describing the location of the
1121#            origin of the orthogonal coordinates in the crystal system
1122#     note that the length of ortholist, useflag and fraclist should be the same
1123# Returns a list with the following elements
1124#   0: a list with three new origin values
1125#   1: the root-mean square difference between the fraclist coordinates and those computed
1126#      using the input values for those atoms where $use is one (in Angstroms)
1127#   2: the computed fractional coordinates for all atoms
1128#   3: individual rms values for all atoms (in Angstroms)
1129# note that items 1-3 are computed with the imput origin, not the revised one
1130proc FitBodyOrigin {Euler cell ortholist useflag fraclist origin} {
1131puts $fraclist
1132    set xform [CalcXformMatrix $Euler $cell]
1133    #puts "entering FitBodyOrigin"
1134    foreach var {x y z} {set sum($var) 0.0}
1135    set i 0
1136    set sumdvs 0
1137    set fracout {}
1138    set rmsout {}
1139    foreach oc $ortholist use $useflag coord $fraclist {
1140        #puts "ortho: $oc"
1141        set frac [lrange [Ortho2Xtal $xform $origin $oc] 3 end]
1142        lappend fracout $frac
1143        if {$use} {incr i}
1144        set dvs 0
1145        foreach var {x y z} v1 $frac v2 $coord abc [lrange $cell 0 2] {
1146            #puts "v2 = $v2"
1147            #puts "v1 = $v1"
1148            #puts "abc = $abc"
1149            set dv [expr {($v2 - $v1)*$abc}]
1150            set dvs [expr {$dvs + $dv*$dv}]
1151            set sumdvs [expr {$sumdvs + $dv*$dv}]
1152            if {$use} {set sum($var) [expr {$sum($var) + $dv/$abc}]}
1153            #puts "round and round"
1154        }
1155        lappend rmsout [expr {sqrt($dvs)}]
1156    }
1157    set rms 0
1158    if {$i > 1} {set rms [expr {sqrt($sumdvs)/$i}]}
1159    set neworig {}
1160    foreach var {x y z} o $origin {
1161        lappend neworig [expr {$o + ($sum($var)/$i)}]
1162    }
1163    return [list $neworig $rms $fracout $rmsout]
1164}
1165
1166# fit a rigid body's Euler angles using least-squares
1167# arguments:
1168#  Euler: a list of axes and angles to rotate: { {axis1 angle1} {axis2 angle2} ...}
1169#              where axis1,... can be 1, 2 or 3 corresponding to the cartesian X, Y or Z axes
1170#  cell: a list with "a b c alpha beta gamma" in Angstroms and degrees
1171#  ortholist: list containing triplets with orthogonal coordinates
1172#  useflag: list of flags to indicate if an atom should be used (1) or ignored (0)
1173#  fraclist: list containing triplets with fractional coordinates 
1174#  origin: a list of fraction coordinates {x y z} describing the location of the
1175#            origin of the orthogonal coordinates in the crystal system
1176#     note that the length of ortholist, useflag and fraclist should be the same
1177# Returns a list of new Euler angles
1178proc FitBodyRot {Euler cell ortholist useflag fraclist origin} {
1179    set xform [CalcXformMatrix $Euler  $cell]
1180    set derivlist [CalcDerivMatrix $Euler  $cell]
1181    set A "2 [expr 3*[llength $ortholist]] 3"
1182    foreach oc $ortholist use $useflag coord $fraclist {
1183        if {! $use} continue
1184        foreach deriv $derivlist {
1185            foreach xyz [lrange [Ortho2Xtal $deriv "0 0 0" $oc] 3 end] {
1186                lappend A $xyz
1187            }
1188        }
1189    }
1190    #puts "A: [La::show $A]"
1191    set y "2 [expr 3*[llength $ortholist]] 1"
1192    foreach oc $ortholist use $useflag coord $fraclist {
1193        if {! $use} continue
1194        set frac [lrange [Ortho2Xtal $xform $origin $oc] 3 end]
1195        foreach xyz $coord XYZ $frac {
1196            lappend y [expr {$XYZ - $xyz}]
1197        }
1198    }
1199
1200    set AtA [La::mmult [La::transpose $A] $A]
1201    set Aty [La::mmult [La::transpose $A] $y]
1202   
1203    set l {}
1204    #set shifts {}
1205    foreach delta [lrange [La::msolve $AtA $Aty] 3 end] item $Euler {
1206        #lappend shifts $delta
1207        lappend l "[lindex $item 0] [expr {$delta + [lindex $item 1]}]"
1208    }
1209    #puts "shifts = $shifts"
1210    return $l
1211}
1212
1213# FitBody: fit a rigid body's Origin and Euler angles
1214# arguments:
1215#  Euler: a list of axes and angles to rotate: { {axis1 angle1} {axis2 angle2} ...}
1216#              where axis1,... can be 1, 2 or 3 corresponding to the cartesian X, Y or Z axes
1217#  cell: a list with "a b c alpha beta gamma" in Angstroms and degrees
1218#  ortholist: list containing triplets with orthogonal coordinates
1219#  useflag: list of flags to indicate if an atom should be used (1) or ignored (0)
1220#  fraclist: list containing triplets with fractional coordinates 
1221#  origin: a list of fraction coordinates {x y z} describing the location of the
1222#            origin of the orthogonal coordinates in the crystal system
1223#     note that the length of ortholist, useflag and fraclist should be the same
1224# Returns a list containing
1225#   new origin
1226#   new Euler angles
1227#   total rms
1228#   fractional coordinates
1229#   rms deviation in fractional coordinates of new Euler angles
1230proc FitBody {Euler cell ortholist useflag fraclist origin "ncycle 5"} {
1231    #puts "start origin = $origin"
1232    foreach {
1233        origin 
1234        startrms
1235        fracout
1236        rmsout } [FitBodyOrigin $Euler $cell $ortholist $useflag $fraclist $origin] {}
1237    #puts "start rms = $startrms"
1238    set rmsprev $startrms
1239    #puts "new origin = $origin"
1240    for {set i 0} {$i < $ncycle} {incr i} {
1241        set Eulerprev $Euler
1242        set Euler [FitBodyRot $Euler $cell $ortholist $useflag $fraclist $origin]
1243        #puts "New Euler $Euler"
1244        #puts "after fit"
1245        foreach {
1246            origin 
1247            rms
1248            fracout
1249            rmsout } [FitBodyOrigin $Euler $cell $ortholist $useflag $fraclist $origin] {}
1250        if {$rms > (1.1 * $rmsprev) + 0.01} {
1251            #puts "rms = $rms, new origin = $origin"
1252            set rmsprev $rms
1253        }
1254    } 
1255    #proc FitBodyOrigin {Euler cell ortholist useflag fraclist origin} 
1256    #return "$neworig $rms $fracout $rmsout"
1257    set fmt  {"%8.5f %8.5f %8.5f     %8.5f %8.5f %8.5f   %6.3f"}
1258    #foreach fracin $fraclist fraccalc $fracout rmsi $rmsout {
1259        #puts "[eval format $fmt $fracin $fraccalc $rmsi]"
1260    #}
1261    return [list $origin $Euler $rms $fracout $rmsout]
1262}
1263
1264# zmat2coord: convert a z-matrix to a set of cartesian coordinates
1265#   a z-matrix is also known as "internal coordinates" or "torsion space"
1266#   (see Journal of Computational Chemistry, Vol 26, #10, p. 1063–1068, 2005 or
1267#    http://www.cmbi.ru.nl/molden/zmat/zmat.html)
1268# INPUT:
1269#   atmlist is a list of ascii lines where each line contains
1270#     lbl c1 distance c2 angle c3 torsion
1271#   where each atom is computed from the previous where the new atom is:
1272#     distance $distance from atom $c1 (angstrom)
1273#     angle $angle from $c1--$c2 (degrees)
1274#     torsion $torsion from $c1--$c2--$c3 (degrees)
1275# OUTPUT:
1276#  zmat2coord returns a list of atom labels and cartesian coordinates,
1277#  with 4 items in each element (label, x, y, z)
1278# this routine was tested against results from Babel via the web interface at
1279# http://www.shodor.org/chemviz/zmatrices/babel.html and sample input at
1280# http://iopenshell.usc.edu/howto/zmatrix/
1281proc zmat2coord {atmlist} { 
1282    set torad [expr {acos(0)/90.}]
1283    set i 0
1284    foreach line $atmlist {
1285        incr i
1286        foreach {lbl c1 dist c2 angle c3 torsion} $line {} 
1287        if {$i == 1} {
1288            set atm(1) [list $lbl 0 0 0] ; # 1st atom is at origin
1289        } elseif {$i == 2} {
1290            set dist1 $dist
1291            set atm(2) [list $lbl $dist1 0 0] ; # 2nd atom is along x-axis
1292        } elseif {$i == 3} {
1293            # 3rd atom can be bonded to the 1st or 2nd
1294            if {$c1 == 1} {
1295                set atm(3) [list $lbl \
1296                                [expr {$dist * cos($torad * $angle)}] \
1297                                [expr {$dist * sin($torad * $angle)}] \
1298                                0]
1299            } else {
1300                set atm(3) [list $lbl \
1301                                [expr {$dist1 - $dist * cos($torad * $angle)}] \
1302                                [expr {$dist * sin($torad * $angle)}] \
1303                                0]
1304            }
1305        } else {
1306            set atm($i) [concat $lbl \
1307                             [ahcat "atm" $c1 $dist $c2 $angle $c3 $torsion]]
1308        }
1309    }
1310    set coordlist {}
1311    foreach key [lsort -integer [array names atm]] {
1312        lappend coordlist $atm($key)
1313    }
1314    return $coordlist
1315}
1316# Compute the length of a vector
1317proc vlen {a} {
1318    set sum 0.0
1319    foreach ai $a {
1320        set sum [expr {$sum + $ai*$ai}]
1321    }
1322    return [expr sqrt($sum)]
1323}
1324# compute vector (a + z * b) and optionally normalize to length d
1325proc vadd {a b d z} {
1326    set c {}
1327    foreach ai $a bi $b {
1328        lappend c [expr {$bi + $z * $ai}]
1329    }
1330    set v [vlen $c]
1331    if {$d != 0} {
1332        set r {}
1333        foreach ci $c {
1334            lappend r [expr {$d * $ci / $v}]
1335        }
1336        return [list $v $r]
1337    }
1338    return [list $v $c]
1339}
1340# normalize a vector
1341proc vnrm {x} {
1342    set v [vlen $x]
1343    if {abs($v) < 1e-8} {return [list 0 0 0]}
1344    set y {}
1345    foreach xi $x {
1346        lappend y [expr {$xi / $v}]
1347    }
1348    return $y
1349}
1350# compute the coordinates for an atom that is bonded:
1351#   distance $dist from atom $nc
1352#   angle $bondang from $nc--$nb
1353#   torsion $torsang from $nc--$nb--$na
1354#   coordinates are found in array $atmarr in the calling routine
1355# based on a Fortran routine provided by Peter Zavalij (Thanks Peter!)
1356proc ahcat {atmarr nc dist nb bondang na torsang} {
1357    upvar 1 $atmarr atm
1358    set xa [lrange $atm($na) 1 3]
1359    set xb [lrange $atm($nb) 1 3]
1360    set xc [lrange $atm($nc) 1 3]
1361    set torad [expr {acos(0)/90.}]
1362    # x = unit Vector A-B
1363    foreach {x1 x2 x3} [lindex [vadd $xb $xa 1. -1.] 1] {}
1364    # y = unit Vector C-B
1365    set y [lindex [vadd $xb $xc 1. -1.] 1]
1366    foreach {y1 y2 y3} $y {}
1367    set z1 [expr {$x2*$y3 - $x3*$y2}]
1368    set z2 [expr {$x3*$y1 - $x1*$y3}]
1369    set z3 [expr {$x1*$y2 - $x2*$y1}]
1370    set z [vnrm [list $z1 $z2 $z3]]
1371    set q1 [expr {$y2*$z3 - $y3*$z2}]
1372    set q2 [expr {$y3*$z1 - $y1*$z3}]
1373    set q3 [expr {$y1*$z2 - $y2*$z1}]
1374    set q [vnrm [list $q1 $q2 $q3]]
1375    set th [expr {$bondang * $torad}]
1376    set ph [expr {-1. * $torsang * $torad}]
1377    set cth [expr {cos($th)}]
1378    set sth [expr {sin($th)}]
1379    set cph [expr {cos($ph)}]
1380    set sph [expr {sin($ph)}]
1381    set xh {}
1382    foreach xci $xc xi $q zi $z yi $y {
1383        lappend xh [expr {
1384                          $xci +
1385                          $dist*($sth*($cph*$xi + $sph*$zi)-$cth*$yi)
1386                      }]
1387    }
1388    return $xh
1389}
1390 
1391# RB2cart: convert the rigid body representation reported as the 2nd element
1392# in ReadRigidBody into cartesian coordinates
1393#   rblist: a list containing an element for each scaling factor
1394# in each element there are four items:
1395#    a multiplier value for the rigid body coordinates
1396#    a damping value (0-9) for the refinement of the multiplier (not used)
1397#    a variable number if the multiplier will be refined (not used)
1398#    a list of cartesian coordinates coordinates
1399# each cartesian coordinate contains 4 items: x,y,z and a label
1400# returns a list of coordinate triplets
1401proc RB2cart {rblist} {
1402    foreach item $rblist {
1403        foreach {mult damp ref coords} $item {}
1404        set i 0
1405        foreach xyz $coords {
1406            foreach {x y z} [lrange $xyz 0 2] {}
1407            foreach val [lrange $xyz 0 2] var {X Y Z} {
1408                if {[array names $var $i] == ""} {
1409                    set ${var}($i) [expr {$mult * $val}]
1410                } else {
1411                    set ${var}($i) [expr {[set ${var}($i)] + $mult * $val}]
1412                }
1413            }
1414            incr i
1415        }
1416    }
1417    set out ""
1418    foreach i [lsort -integer [array names X]] {
1419        lappend out [list $X($i) $Y($i) $Z($i)]
1420    }
1421    return $out
1422}
1423
1424# get the name of the DRAWxtl application, if installed
1425proc GetDRAWxtlApp {} {
1426    # is DRAWxtl installed?
1427    set app {}
1428    if {![catch {set fp [open [file join $::env(HOME) .drawxtlrc] r]}]} {
1429        # line 12 is name of executable
1430        set i 0
1431        while {$i < 12} {
1432            incr i
1433            gets $fp appname
1434        }
1435        close $fp
1436        set app [auto_execok $appname]
1437    }
1438    if {$app != ""} {
1439        return $appname
1440    }
1441    return ""
1442}
1443
1444# DRAWxtlPlotOrtho: plot orthogonal coordinates in DRAWxtl
1445# input:
1446#  filename: file name for the .str file to create
1447#  title: string for title in .str file
1448#  coords: cartesian coordinates
1449#  bondlist: list of bonds to draw as min, max length (A) and
1450#      an optional color; for example: {{1.4 1.6} {1.2 1.3 Red}}
1451proc DRAWxtlPlotOrtho {filename title coords bondlist} {
1452    foreach {xmin ymin zmin} {"" "" ""} {}
1453    foreach {xmax ymax zmax} {"" "" ""} {}
1454    foreach xyz $coords {
1455        foreach {x y z} $xyz {}
1456        foreach s {x y z} {
1457            foreach t {min max} {
1458                if {[set ${s}${t}] == ""} {set ${s}${t} [set $s]}
1459            } 
1460            if {[set ${s}min] > [set $s]} {set ${s}min [set $s]}
1461            if {[set ${s}max] < [set $s]} {set ${s}max [set $s]}
1462        }
1463    }
1464    #puts "$xmin $xmax $ymin $ymax $zmin $zmax"
1465    set max $xmin
1466    foreach val "$xmin $xmax $ymin $ymax $zmin $zmax" {
1467        if {$max < abs($val)} {set max $val}
1468    }
1469    set scale [expr {4.*$max}]
1470    set a 10.
1471    lappend range [expr -0.01+($xmin/$scale)] [expr 0.01+($xmax/$scale)] \
1472        [expr -0.01+($ymin/$scale)] [expr 0.01+($ymax/$scale)] \
1473        [expr -0.01+($zmin/$scale)] [expr 0.01+($zmax/$scale)]
1474    set fp [open $filename w]
1475    puts $fp "title $title"
1476    puts $fp "box  0.000 Black"
1477    puts $fp "background White"
1478    #puts $fp "nolabels"
1479    puts $fp "cell $a $a $a 90 90 90"
1480    puts $fp "spgr P 1"
1481    puts $fp "pack $range"
1482    set i 0
1483    foreach xyz $coords {
1484        foreach {x y z} $xyz {}
1485        incr i
1486        puts $fp "atom c $i [expr {$x/$scale}] [expr {$y/$scale}] [expr {$z/$scale}]"
1487        puts $fp "labeltext [expr {0.02 + $x/$scale}] [expr {0.01 + $y/$scale}] [expr {0.01 + $z/$scale}] $i"
1488    }
1489    puts $fp "sphere c  [expr 0.100*($a/$scale)] Red"
1490    puts $fp "finish   0.70   0.30   0.08   0.01"
1491    foreach bondpair $bondlist {
1492        foreach {b1 b2 color} $bondpair {}
1493        if {$color == ""} {set color Red}
1494        puts $fp "bond c c [expr {0.01*$a/$scale}] [expr {$b1*$a/$scale}] [expr {$b2*$a/$scale}] $color"
1495    }
1496    puts $fp "frame"
1497    set range {}
1498    lappend range -0.01 [expr 0.01+(0.1*$a/$scale)] \
1499        -0.01 [expr 0.01+(0.1*$a/$scale)] \
1500        -0.01 [expr 0.01+(0.1*$a/$scale)]
1501    puts $fp "cell $a $a $a 90 90 90"
1502    puts $fp "spgr P 1"
1503    puts $fp "pack $range"
1504    puts $fp "atom o 1 0 0 0"
1505    puts $fp "atom o 2 [expr {0.1*$a/$scale}] 0 0"
1506    puts $fp "atom o 3 0 [expr {0.1*$a/$scale}] 0"
1507    puts $fp "atom o 4 0 0 [expr {0.1*$a/$scale}]"
1508    puts $fp "bond o o [expr {0.01*$a/$scale}] [expr {-0.1 + $a/$scale}] [expr {0.1 + $a/$scale}] Black"
1509    puts $fp "labelscale 0.5"
1510    puts $fp "labeltext [expr {0.11*$a/$scale}] 0 0 x"
1511    puts $fp "labeltext 0 [expr {0.11*$a/$scale}] 0 y"
1512    puts $fp "labeltext 0 0 [expr {0.11*$a/$scale}] z"
1513    puts $fp "sphere o [expr {0.02*$a/$scale}] Blue"
1514    puts $fp "origin   .0 .0 .0"
1515    puts $fp "end"
1516    close $fp
1517}
1518
1519# PlotRBtype: plot a rigid body in DRAWxtl
1520# input:
1521#  rbtype: # of rigid body
1522#  bondlist: list of bonds to draw as min, max length (A) and
1523#      an optional color; for example: {{1.4 1.6} {1.2 1.3 Red}}
1524#  file: file name for the .str file to create
1525proc PlotRBtype {rbtype "bondlist {}" "file {}"} {
1526    set app [GetDRAWxtlApp]
1527    if {$app == ""} {
1528        MyMessageBox -parent . -title "No DRAWxtl" \
1529                -message "Sorry, DRAWxtl is not installed" \
1530                -icon warning
1531        return
1532    }
1533    if {$::tcl_platform(platform) == "windows" && $file == ""} {
1534        set file [file join [pwd] rbplot.str]
1535    } else {
1536        set file "/tmp/rbplot.str"
1537    }
1538    set coords [RB2cart [lindex [ReadRigidBody $rbtype] 1]]
1539    DRAWxtlPlotOrtho $file "" $coords $bondlist
1540    if {$app != ""} {exec $app $file &}
1541}
1542
1543# PlotRBcoords: plot orthogonal coordinates in DRAWxtl
1544# input:
1545#  coords: cartesian coordinates
1546#  bondlist: list of bonds to draw as min, max length (A) and
1547#      an optional color; for example: {{1.4 1.6} {1.2 1.3 Red}}
1548#  file: file name for the .str file to create
1549proc PlotRBcoords {coords "bondlist {}" "file {}"} {
1550    set app [GetDRAWxtlApp]
1551    if {$app == ""} {
1552        MyMessageBox -parent . -title "No DRAWxtl" \
1553                -message "Sorry, DRAWxtl is not installed" \
1554                -icon warning
1555        return
1556    }
1557    if {$::tcl_platform(platform) == "windows" && $file == ""} {
1558        set file [file join [pwd] rbplot.str]
1559    } else {
1560        set file "/tmp/rbplot.str"
1561    }
1562    DRAWxtlPlotOrtho $file "" $coords $bondlist
1563    if {$app != ""} {exec $app $file &}
1564}
1565
1566# DRAWxtlPlotRBFit: plot a set of fraction coordinates superimposed
1567# on a structure read from a phase
1568# input:
1569#  RBcoords: fractional coordinates for rigid body
1570#  phase:# of phase to plot
1571#  firstatom: seq # of 1st atom in structure to be mapped to rigid body
1572#  allatoms: 0 to plot only atoms in phase that are in the rigid body,
1573#      otherwise plot all atoms
1574#  bondlist: list of bonds to draw for the phase as min, max length (A) and
1575#      an optional color; for example: {{1.4 1.6} {1.2 1.3 Red}}
1576#  rbbondlist: list of bonds to draw for the phase as min, max length (A) and
1577#      an optional color; for example: {{1.4 1.6} {1.2 1.3 Red}}
1578#  file: optional file name for the .str file to create
1579proc DRAWxtlPlotRBFit {RBcoords phase firstatom "allatoms 0" \
1580                           "bondlist {}" "rbbondlist {}" "file {}"} {
1581    set natom [llength $RBcoords]
1582    set app [GetDRAWxtlApp]
1583    if {$app == ""} {
1584        MyMessageBox -parent . -title "No DRAWxtl" \
1585                -message "Sorry, DRAWxtl is not installed" \
1586                -icon warning
1587        return
1588    }
1589    if {$::tcl_platform(platform) == "windows" && $file == ""} {
1590        set file [file join [pwd] rbplot.str]
1591    } else {
1592        set file "/tmp/rbfit.str"
1593    }
1594
1595    # get rigid body coordinate range
1596    foreach {xmin ymin zmin} {"" "" ""} {}
1597    foreach {xmax ymax zmax} {"" "" ""} {}
1598    foreach xyz $RBcoords {
1599        foreach {x y z} $xyz {}
1600        foreach s {x y z} {
1601            foreach t {min max} {
1602                if {[set ${s}${t}] == ""} {set ${s}${t} [set $s]}
1603            } 
1604            if {[set ${s}min] > [set $s]} {set ${s}min [set $s]}
1605            if {[set ${s}max] < [set $s]} {set ${s}max [set $s]}
1606        }
1607    }
1608    set rbrange {}
1609    foreach val [list [expr -0.01+$xmin] [expr 0.01+$xmax] \
1610                     [expr -0.01+$ymin] [expr 0.01+$ymax] \
1611                     [expr -0.01+$zmin] [expr 0.01+$zmax] ] {
1612        append rbrange [format " %8.4f" $val]
1613    }
1614    set rbcenter [list [expr {($xmin+$xmax)/2}] \
1615                      [expr {($ymin+$ymax)/2}] \
1616                      [expr {($zmin+$zmax)/2}] ]
1617    # get matching atoms coordinate range
1618    set firstind [lsearch $::expmap(atomlist_$phase) $firstatom]
1619    set matchedatomlist [lrange \
1620                      [lrange $::expmap(atomlist_$phase) $firstind end] \
1621                      0 [expr {$natom-1}]]
1622    foreach atom $matchedatomlist {
1623        foreach s {x y z} {
1624            set $s [atominfo $phase $atom $s]
1625            foreach t {min max} {
1626                if {[set ${s}${t}] == ""} {set ${s}${t} [set $s]}
1627            } 
1628            if {[set ${s}min] > [set $s]} {set ${s}min [set $s]}
1629            if {[set ${s}max] < [set $s]} {set ${s}max [set $s]}
1630        }
1631    }
1632    # expand to cover at least one unit cell
1633    foreach var {xmin ymin zmin} { 
1634        if {[set $var] > 0.0} {set $var 0.0}
1635    }
1636    foreach var {xmax ymax zmax} { 
1637        if {[set $var] < 1.} {set $var 1.}
1638    }
1639    set range {}
1640    foreach val [list [expr -0.01+$xmin] [expr 0.01+$xmax] \
1641                     [expr -0.01+$ymin] [expr 0.01+$ymax] \
1642                     [expr -0.01+$zmin] [expr 0.01+$zmax]] {
1643        append range [format " %8.4f" $val]
1644    }
1645
1646    set fp [open $file w]
1647    puts $fp "title structure/rigid-body fit plot"
1648    # plot the structure
1649    puts -nonewline $fp "cell"
1650    foreach p {a b c alpha beta gamma} {
1651        puts -nonewline $fp " [phaseinfo $phase $p]"
1652    }
1653    puts $fp ""
1654    puts $fp "spgp [phaseinfo $phase spacegroup]"
1655    puts $fp "pack $range"
1656    if {$allatoms != 0} {
1657        set atoms $::expmap(atomlist_$phase)
1658    } else {
1659        set firstind [lsearch $::expmap(atomlist_$phase) $firstatom]
1660        set atoms [lrange \
1661                       [lrange $::expmap(atomlist_$phase) $firstind end] \
1662                       0 [expr {$natom-1}]]
1663    }
1664
1665    # set origin at center of rigid body
1666    puts $fp "origin  $rbcenter"
1667    # now loop over atoms
1668    foreach atom $atoms {
1669        set type [atominfo $phase $atom type]
1670        set typelist($type) 1
1671        set xyz ""
1672        foreach v {x y z} {
1673            append xyz "[atominfo $phase $atom $v] "
1674        }
1675        puts $fp "atom $type $atom $xyz"
1676        if {[lsearch $matchedatomlist $atom] != -1} {
1677            puts $fp "labeltext $xyz $atom"
1678        }
1679               
1680        set uiso [atominfo $phase $atom Uiso]
1681        # are there anisotropic atoms? If so convert them to Uequiv
1682        if {[atominfo $phase $atom temptype] == "A"} {
1683            puts -nonewline $fp "Uij [atominfo $phase $atom type] $atom "
1684            foreach v {U11 U22 U33 U12 U13 U23} {
1685                puts -nonewline $fp "[atominfo $phase $atom $v] "
1686            }
1687            puts $fp ""
1688        }
1689    }
1690
1691    foreach type [array names typelist] color {Green Blue Magenta Cyan} {
1692        if {$type == ""} break
1693        puts $fp "sphere $type 0.1 $color"
1694    }
1695    foreach type [array names typelist] color1 {Green Blue Magenta Cyan} {
1696        foreach bondpair $bondlist {
1697            foreach {b1 b2 color} $bondpair {}
1698            if {$color == ""} {set color $color1}
1699            puts $fp "bond $type $type 0.02 $b1 $b2 $color"
1700        }
1701        foreach type1 [array names typelist] {
1702            if {$type1 == $type} break
1703            foreach bondpair $bondlist {
1704                foreach {b1 b2 color} $bondpair {}
1705                if {$color == ""} {set color $color1}
1706                puts $fp "bond $type $type1 0.02 $b1 $b2 $color"
1707            }
1708        }
1709    }
1710    # plot the rigid body
1711    puts $fp "frame"
1712    puts -nonewline $fp "cell"
1713    foreach p {a b c alpha beta gamma} {
1714        puts -nonewline $fp " [phaseinfo $phase $p]"
1715    }
1716    puts $fp ""
1717    puts $fp "background White"
1718    #puts $fp "nolabels"
1719    puts $fp "labelscale 0.5"
1720    puts $fp "spgr P 1"
1721    puts $fp "pack $rbrange"
1722    set i 0
1723    foreach xyz $RBcoords {
1724        foreach {x y z} $xyz {}
1725        incr i
1726        puts $fp "atom c $i $x $y $z"
1727        puts $fp "labeltext $x $y $z r$i"
1728    }
1729    foreach bondpair $rbbondlist {
1730        foreach {b1 b2 color} $bondpair {}
1731        if {$color == ""} {set color Red}
1732        puts $fp "bond c c 0.02 $b1 $b2 $color"
1733    }
1734
1735    puts $fp "sphere c 0.05 Red"
1736    puts $fp "finish   0.70   0.30   0.08   0.01"
1737    puts $fp "end"
1738
1739    #puts $fp "bond o o [expr {0.01*$a/$scale}] [expr {-0.1 + $a/$scale}] [expr {0.1 + $a/$scale}] Black"
1740    close $fp
1741    MyMessageBox -parent . -title "Info" \
1742                -message "Note that the phase is drawn in green, blue, cyan & magenta and the rigid body in red."
1743    if {$app != ""} {exec $app $file &}
1744}
1745
1746
1747#AddRigidBody {1} { {{0 0 0 xe} {1 1 1 o} {2 2 2 si+4}} }
1748#puts [GetRB 1 6 8 "1 2" "X 1 2" "Y 1 3"]
1749#puts [GetRB 1 4 8 "1" "X 1 2" "Z 3 4"]
1750#MapRigidBody 1 1 7 ".11 .22 .33" "11 12 13"
1751
1752
1753#AddRigidBody {1} { {
1754#    {1 1 1 o} {-1 1 1 o} {1 -1 1 o} {-1 -1 1 o}
1755#    {1 1 -1 o} {-1 1 -1 o} {1 -1 -1 o} {-1 -1 -1 o}
1756#} }
1757#set n [MapRigidBody 1 1 1 ".2 .3 .4" "13 17 19"]
1758#puts "body $n created"
1759#incr expgui(changed)
1760#RunRecalcRBCoords
1761#puts "press Enter to continue"
1762#gets stdin line
1763#MapRigidBody 1 1 $n ".5 .5 .5" "0 0 0"
1764#incr expgui(changed)
1765#RunRecalcRBCoords
1766
1767#puts "Test FitBody"
1768set fraclist {
1769    { 0.5483305238484277 0.4887545024531055 0.6167996784631056 }
1770    { 0.1036801409356145 0.5954016321779562 0.5129448102437683 }
1771    { 0.26404665760133855 0.09455414439078394 0.612655365147539 }
1772    { -0.18060372531147473 0.20120127411563465 0.5088004969282018 }
1773    { 0.5806037253114747 0.3987987258843653 0.2911995030717982 }
1774    { 0.13595334239866147 0.5054458556092161 0.18734463485246095 }
1775    { 0.2963198590643855 0.004598367822043814 0.2870551897562318 }
1776    { -0.1483305238484277 0.1112454975468945 0.1832003215368945 }
1777}
1778set ortholist {
1779    {1 1 1} 
1780    {-1 1 1}
1781    {      1.000000   -1.000000    1.000000}
1782    {     -1.000000   -1.000000    1.000000}
1783    {      1.000000    1.000000   -1.000000}
1784    {     -1.000000    1.000000   -1.000000}
1785    {      1.000000   -1.000000   -1.000000}
1786    {     -1.000000   -1.000000   -1.000000} 
1787}
1788# test code, generates DRAWxtl imput file from orthogonal coordinate list
1789# with bonds of ~2, 2.8 and 3.4 A
1790#DRAWxtlPlotOrtho test4.str "test file" $ortholist {{1.9 2.1} {3.4 3.5 Blue} {2.8 2.83 Green} }
1791
1792# test code, plots rigid body type #2 with bonds drawn at ~1.3 & 2 A
1793#PlotRBtype 2 {{1.9 2.1} {1.28 1.32}}
1794
1795# test code, plots rigid body coords in ortholist with bonds @  ~2, 2.8 and 3.4 A
1796#PlotRBcoords $ortholist {{1.9 2.1} {3.4 3.5 Blue} {2.8 2.83 Green} }
1797
1798
1799set useflag {1 1 1 1 1 1 1 1}
1800set cell {4.  5695100105.}
1801#set origin ".20 .30 .40"
1802set origin ".0 .0 .0"
1803#set Euler  {{1 13} {2 17} {3 19}}
1804#set Euler  {{1 0} {2 180} {3 0}}
1805set Euler  {{1 0} {2 0} {3 0}}
1806
1807#puts [La::show $xform]
1808#puts "out: [FitBody $Euler $cell $ortholist $useflag $fraclist $origin 30]"
1809
1810
1811# test zmat2coord
1812set atmlist {
1813    {C1 0 0.0 0 0.0 0 0.0}
1814    {O2 1 1.20 0 0.0 0 0.0}
1815    {H3 1 1.10 2 120.0 0 0.0}
1816    {C4 1 1.50 2 120.0 3 180.0}
1817    {H5 4 1.10 1 110.0 2 0.00}
1818    {H6 4 1.10 1 110.0 2 120.0}
1819    {H7 4 1.10 1 110.0 2 -120.0}
1820}
1821#  C        0.00000        0.00000        0.00000
1822#  O        1.20000        0.00000        0.00000
1823#  H       -0.55000        0.95263        0.00000
1824#  C       -0.75000       -1.29904       -0.00000
1825#  H       -0.04293       -2.14169       -0.00000
1826#  H       -1.38570       -1.36644        0.89518
1827#  H       -1.38570       -1.36644       -0.89518
1828# set coordlist [zmat2coord $atmlist]
1829 set i 0
1830# puts "\nZmatrix in"
1831# foreach line $atmlist {
1832#     incr i
1833#     puts "$i) $line"
1834# }
1835# puts "Cartesian out"
1836# foreach line $coordlist {
1837#     puts [eval format "%-4s%10.5f%10.5f%10.5f" $line]
1838# }
1839
1840# AddRigidBody {1 0.75} {
1841#     {
1842#       {1 1 1 c}
1843#       {-1 1 1 c}
1844#       {      1.000000   -1.000000    1.000000 c}
1845#       {     -1.000000   -1.000000    1.000000 c}
1846#       {      1.000000    1.000000   -1.000000 c}
1847#       {     -1.000000    1.000000   -1.000000 c}
1848#       {      1.000000   -1.000000   -1.000000 c}
1849#       {     -1.000000   -1.000000   -1.000000 c}
1850#       {1 1 1 h}
1851#       {1 -1 -1 h}
1852#       {-1 1 -1 h}
1853#       {-1 -1 1 h}
1854#     } {
1855#       {0 0 0 c }
1856#       {0 0 0 c}
1857#       {0 0 0 c}
1858#       {0 0 0 c}
1859#       {0 0 0 c}
1860#       {0 0 0 c}
1861#       {0 0 0 c}
1862#       {0 0 0 c}
1863#       {1 1 1 h}
1864#       {1 -1 -1 h}
1865#       {-1 1 -1 h}
1866#       {-1 -1 1 h}
1867#     }
1868# }
1869# MapRigidBody 2 2 1 {0 0 0} {10 15 20}
Note: See TracBrowser for help on using the repository browser.